init

1 files changed, 40 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..390961a17831
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,40 @@
+# Maintainer: Sainnhe Park <sainnhe@gmail.com>
+_variant='neovim'
+_extname=coc-pyright
+_packdir="usr/local/share/nvim/site/pack/coc/start/${_extname}"
+url='https://github.com/fannheyward/coc-pyright'
+pkgdesc='Pyright extension for coc.nvim'
+
+pkgname="${_variant}-${_extname}-git"
+provides=("${_variant}-${_extname}")
+conflicts=("${_variant}-${_extname}")
+arch=('any')
+depends=("${_variant}-coc" 'git')
+makedepends=('yarn' 'npm')
+license=('')
+source=("${_extname}::git+${url}.git")
+pkgver=r203.172e760
+pkgrel=1
+sha256sums=('SKIP')
+
+pkgver() {
+    cd "${srcdir}/${_extname}"
+    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+build() {
+    cd "${srcdir}/${_extname}"
+    yarn install --frozen-lockfile
+    yarn pack
+    tar xvf *.tgz
+    rm *.tgz
+    cd package
+    npm install --only=production --no-lockfile --ignore-scripts
+}
+
+package() {
+    cd "${srcdir}/${_extname}/package"
+    find . -type f -exec \
+        install -Dm 644 '{}' "${pkgdir}/${_packdir}/{}" \;
+    rm -rf "${srcdir}/${_extname}/package"
+}