newpkg: net-tools-git 1.60.r364.g479bb4a-1

1 files changed, 43 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..fad5b7e42d85
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,43 @@
+# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
+
+pkgname=net-tools-git
+pkgver=1.60.r364.g479bb4a
+pkgrel=1
+pkgdesc="The collection of base networking utilities for Linux"
+arch=('i686' 'x86_64')
+url="http://net-tools.sourceforge.net/"
+license=('GPL2')
+depends=('glibc' 'gettext')
+makedepends=('git')
+provides=('net-tools')
+conflicts=('net-tools')
+source=("git+https://git.code.sf.net/p/net-tools/code")
+sha256sums=('SKIP')
+
+
+pkgver() {
+  cd "code"
+
+  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+  cd "code"
+
+  yes "" | make config
+  make
+}
+
+package() {
+  cd "code"
+
+  make DESTDIR="$pkgdir" BINDIR="/usr/bin" SBINDIR="/usr/bin" install
+
+  # provided by yp-tools
+  rm "$pkgdir/usr/bin"/{nis,yp}domainname
+  rm "$pkgdir/usr/share/man/man1"/{nis,yp}domainname.1
+
+  # provided by inetutils
+  rm "$pkgdir/usr/bin"/{hostname,dnsdomainname,domainname}
+  rm -r "$pkgdir/usr/share/man/man1"
+}