113.24.00-1: Initial upload

1 files changed, 35 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..81cc7435757d
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,35 @@
+# Maintainer: Jakob Gahde <j5lx@fmail.co.uk>
+
+pkgname=ocaml-ppx_driver
+pkgver=113.24.00
+pkgrel=1
+license=('Apache')
+arch=('i686' 'x86_64')
+pkgdesc="Feature-full driver for OCaml AST transformers"
+url="https://github.com/janestreet/ppx_driver"
+depends=('ocaml' 'ocaml-ppx_core' 'ocaml-ppx_optcomp')
+makedepends=('ocaml-findlib' 'opam')
+source=("https://ocaml.janestreet.com/ocaml-core/$(echo ${pkgver} | grep -Po "^[0-9]+\.[0-9]+")/files/${pkgname#ocaml-}-$(echo ${pkgver} | grep -Po "^[0-9]+\.[0-9]+\.[0-9]+").tar.gz"
+        "libdir.patch")
+options=('!strip')
+md5sums=('dd5f40bef1c6d0cd3e78da9aac420209'
+         '7f0a951f1ac87385272ea7a6dd58762a')
+
+prepare() {
+  cd "${srcdir}/${pkgname#ocaml-}-${pkgver}"
+
+  patch -Np1 < "${srcdir}/libdir.patch"
+}
+
+build() {
+  cd "${srcdir}/${pkgname#ocaml-}-${pkgver}"
+
+  ./configure --prefix=/usr
+  make
+}
+
+package() {
+  cd "${srcdir}/${pkgname#ocaml-}-${pkgver}"
+
+  make install PREFIX="${pkgdir}/usr" LIBDIR="${pkgdir}$(ocamlc -where)"
+}