Initial commit

1 files changed, 34 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..b9c0256186b7
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,34 @@
+# Maintainer: Andrew O'Neill <andrew at meanjollies dot com>
+
+pkgname=oci-cli
+pkgver=2.4.27
+pkgrel=1
+pkgdesc='Command line interface for Oracle Cloud Infrastructure'
+arch=('any')
+url='https://github.com/oracle/oci-cli'
+license=('Apache')
+depends=('python' 'python-oci' 'python-arrow' 'python-certifi' 'python-click' 'python-dateutil' 'python-cryptography' 'python-pyopenssl' 'python-jmespath' 'python-terminaltables' 'python-httpsig_cffi' 'python-idna' 'python-pytz' 'python-requests' 'python-six' 'python-retrying')
+makedepends=('python-setuptools')
+source=("${url}/archive/v${pkgver}.tar.gz"
+        "${pkgname}.patch")
+sha256sums=('af605bd869547fc02789caf1f2ca85470688b67b3596be569a51c5d1c0b92b4e'
+            '0ce702725d8a78edda01f2a55792f0d29bc6521bdaf56108b44d4b5dea88f912')
+
+prepare() {
+  cd "${pkgname}-${pkgver}"
+
+  patch -p1 -i ../${pkgname}.patch
+}
+
+build() {
+  cd "${pkgname}-${pkgver}"
+
+  python setup.py build
+}
+
+package() {
+  cd "${pkgname}-${pkgver}"
+
+  python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
+  install -Dm644 LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}