Initial commit

1 files changed, 41 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..48bed6aac268
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,41 @@
+# Maintainer: Anthony Wang <ta180m@pm.me>
+
+_pkgname=opencontest-server
+pkgname=opencontest-server-git
+pkgver=v2.5.3_2_ge2c3b5f
+pkgrel=1
+pkgdesc="An OpenContest server written in Python"
+arch=(any)
+url="https://github.com/LadueCS/OpenContest-Server"
+license=('AGPL')
+makedepends=('python-setuptools' 'python-dephell')
+depends=('python' 'python-requests' 'firejail')
+source=("$_pkgname::git+$url.git")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "$srcdir/$_pkgname"
+  git describe --tags --long | sed s/-/_/g
+}
+
+prepare() {
+  cd "$srcdir/$_pkgname"
+
+  dephell deps convert --from pyproject.toml --to setup.py
+}
+
+build() {
+  cd "$srcdir/$_pkgname"
+
+  python setup.py build
+}
+
+package() {
+  cd "$srcdir/$_pkgname"
+
+  python setup.py install --root="$pkgdir" --optimize=1
+
+  install -vDm644 systemd.service "$pkgdir/usr/lib/systemd/system/$_pkgname.service"
+  install -vDm644 sysusers.conf "$pkgdir/usr/lib/sysusers.d/$_pkgname.conf"
+  install -vDm644 tmpfiles.conf "$pkgdir/usr/lib/tmpfiles.d/$_pkgname.conf"
+}