Create packetbeat-bin

1 files changed, 35 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..4670fcbbb10c
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,35 @@
+# Maintainer: Tyler Langlois <ty at tjll dot net>
+
+pkgname=packetbeat-bin
+_pkgbase=${pkgname%%-bin}
+pkgver=1.0.0_beta3
+_pkgver=${pkgver/_/-}
+pkgrel=1
+pkgdesc='An open source network packet analyzer that ships data to Elasticsearch (precompiled)'
+arch=('i686' 'x86_64')
+url="https://www.elastic.co/products/beats/$_pkgbase"
+license=('APACHE')
+backup=("etc/$_pkgbase/$_pkgbase.yml")
+optdepends=('elasticsearch: for running standalone installation')
+options=('!strip')
+provides=('packetbeat')
+conflicts=('packetbeat')
+source=("$_pkgbase.service")
+sha256sums=('09420676932fd4292351c9b55e835c545013477d015b7ffe8d5009ed1984da64')
+
+source_i686=("https://download.elastic.co/beats/$_pkgbase/$_pkgbase-$_pkgver-i686.tar.gz")
+source_x86_64=("https://download.elastic.co/beats/$_pkgbase/$_pkgbase-$_pkgver-x86_64.tar.gz")
+sha256sums_i686=('6505bd0e7a103398ca512ca4292667dd89f44237ba8b9095a6e2b8592b0e4906')
+sha256sums_x86_64=('11ec87cd0164c6bf4061fc2a1b28cd3e0c8a9a02009882f71fb0cde8e3d525b2')
+
+package() {
+    cd "$srcdir/$_pkgbase-$_pkgver-$CARCH"
+
+    install -D -m755 $_pkgbase     "$pkgdir/usr/bin/$_pkgbase"
+    install -D -m644 $_pkgbase.yml "$pkgdir/etc/$_pkgbase/$_pkgbase.yml"
+    install -D -m644 $_pkgbase.template.json \
+                     "$pkgdir/etc/$_pkgbase/$_pkgbase.template.json"
+
+    install -D -m644 "$srcdir/$_pkgbase.service" \
+                     "$pkgdir/usr/lib/systemd/system/$_pkgbase.service"
+}