update applications-menu again

1 files changed, 45 insertions, 32 deletions

diff --git a/PKGBUILD b/PKGBUILD
index cf12c380be1f..c7ddf07db72c 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,55 +1,68 @@
 # Maintainer: Maxime Gauduin <alucryd@archlinux.org>
 
 pkgname=pantheon-applications-menu-git
-pkgver=r1111.ff1d629
+pkgver=2.4.2.r6.58cd96a
 pkgrel=1
 pkgdesc='The Pantheon Application Menu'
-arch=('i686' 'x86_64')
-url='https://github.com/elementary/applications-menu'
-license=('GPL3')
-groups=('pantheon-unstable')
-depends=('appstream' 'gdk-pixbuf2' 'glib2' 'glibc' 'gnome-menus' 'gtk3'
-         'json-glib' 'libgee' 'libsoup' 'plank' 'zeitgeist'
-         'libgranite.so' 'libswitchboard-2.0.so' 'libwingpanel-2.0.so')
-makedepends=('cmake' 'git' 'granite-git' 'switchboard-git' 'vala'
-             'wingpanel-git')
-provides=('pantheon-applications-menu')
-conflicts=('pantheon-applications-menu' 'slingshot-launcher')
-replaces=('slingshot-launcher-bzr')
-source=('pantheon-applications-menu::git+https://github.com/elementary/applications-menu.git')
-sha256sums=('SKIP')
+arch=(x86_64)
+url=https://github.com/elementary/applications-menu
+license=(GPL3)
+groups=(pantheon-unstable)
+depends=(
+  appstream
+  gdk-pixbuf2
+  glib2
+  gnome-menus
+  gtk3
+  json-glib
+  libgee
+  libgranite.so
+  libsoup
+  libswitchboard-2.0.so
+  libwingpanel-2.0.so
+  plank
+  zeitgeist
+)
+makedepends=(
+  git
+  meson
+  granite-git
+  switchboard-git
+  vala
+  wingpanel-git
+)
+provides=(pantheon-applications-menu)
+conflicts=(pantheon-applications-menu)
+source=(
+  pantheon-applications-menu::git+https://github.com/elementary/applications-menu.git
+  pantheon-applications-menu-plank.patch
+)
+sha256sums=(
+  SKIP
+  bf9c6e4eb7bb236e3d740ca8a2e86558ede3efe460a0a44a7ef14a84090b9d5a
+)
 
 pkgver() {
   cd pantheon-applications-menu
 
-  echo "r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
+  git describe --tags | sed 's/-/.r/; s/-g/./'
 }
 
 prepare() {
   cd pantheon-applications-menu
 
-  if [[ -d build ]]; then
-    rm -rf build
-  fi
-  mkdir build
+  patch -Np1 -i ../pantheon-applications-menu-plank.patch
 }
 
 build() {
-  cd pantheon-applications-menu/build
-
-  cmake .. \
-    -DCMAKE_BUILD_TYPE='Release' \
-    -DCMAKE_INSTALL_PREFIX='/usr' \
-    -DCMAKE_INSTALL_LIBDIR='/usr/lib' \
-    -DGSETTINGS_COMPILE='OFF' \
-    -DUSE_UNITY='OFF'
-  make
+  arch-meson pantheon-applications-menu build \
+    -D b_pie=false \
+    -D with-unity=false
+  ninja -C build
 }
 
 package() {
-  cd pantheon-applications-menu/build
-
-  make DESTDIR="${pkgdir}" install
+  DESTDIR="${pkgdir}" meson install -C build
 }
 
 # vim: ts=2 sw=2 et: