Initial import

1 files changed, 62 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..1acf9ccb229a
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,62 @@
+# Maintainer: Andy Weidenbaum <archbaum@gmail.com>
+
+pkgname=perl6-compress-brotli
+pkgver=0.1.0
+pkgrel=1
+pkgdesc="Perl6 support for Brotli Encoding"
+arch=('i686' 'x86_64')
+depends=('perl6')
+checkdepends=('perl')
+makedepends=('alacryd'
+             'autoconf'
+             'automake'
+             'gcc'
+             'git'
+             'libtool'
+             'make'
+             'perl6-librarymake')
+groups=('perl6')
+url="https://github.com/sylvarant/Compress-Brotli"
+license=('PerlArtistic')
+source=($pkgname-$pkgver::git+https://github.com/sylvarant/Compress-Brotli)
+sha256sums=('SKIP')
+
+build() {
+  cd "$srcdir/$pkgname-$pkgver"
+
+  msg2 'Building...'
+  cd stub && make
+}
+
+check() {
+  cd "$srcdir/$pkgname-$pkgver"
+
+  msg2 'Running tests...'
+  PERL6LIB=lib prove -r -e perl6
+}
+
+package() {
+  cd "$srcdir/$pkgname-$pkgver"
+
+  msg2 'Installing documentation...'
+  install -Dm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
+
+  msg2 'Installing...'
+  install -dm 755 "$pkgdir/usr/share/perl6/vendor"
+  export RAKUDO_LOG_PRECOMP=1
+  export PERL6LIB="inst#$pkgdir/usr/share/perl6/vendor"
+  alacryd install
+
+  msg2 'Removing redundant precomp file dependencies...'
+  _precomp=($(pacman -Qg perl6 \
+    | awk '{print $2}' \
+    | xargs pacman -Ql \
+    | awk '{print $2}' \
+    | grep precomp))
+  for _pc in "${_precomp[@]}"; do
+    [[ -f "$pkgdir/$_pc" ]] && rm -f "$pkgdir/$_pc"
+  done
+
+  msg2 'Cleaning up pkgdir...'
+  find "$pkgdir" -type f -name "*.lock" -exec rm '{}' \;
+}