Initial import

1 files changed, 51 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..b228b2942c05
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,51 @@
+# Maintainer: Andy Weidenbaum <archbaum@gmail.com>
+
+pkgname=perl6-file-compare
+pkgver=0.0.1
+pkgrel=1
+pkgdesc="Compare files to check for equality/difference"
+arch=('any')
+depends=('rakudo')
+checkdepends=('perl')
+makedepends=('alacryd' 'git')
+groups=('perl6')
+url="https://github.com/labster/perl6-File-Compare"
+license=('PerlArtistic')
+source=($pkgname-$pkgver::git+https://github.com/labster/perl6-File-Compare)
+sha256sums=('SKIP')
+
+check() {
+  cd "$srcdir/$pkgname-$pkgver"
+
+  msg2 'Running tests...'
+  PERL6LIB=lib prove -r -e perl6
+}
+
+package() {
+  cd "$srcdir/$pkgname-$pkgver"
+
+  msg2 'Installing license...'
+  install -Dm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
+
+  msg2 'Installing documentation...'
+  install -Dm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
+
+  msg2 'Installing...'
+  install -dm 755 "$pkgdir/usr/share/perl6/vendor"
+  export RAKUDO_LOG_PRECOMP=1
+  export PERL6LIB="inst#$pkgdir/usr/share/perl6/vendor"
+  alacryd install
+
+  msg2 'Removing redundant precomp file dependencies...'
+  _precomp=($(pacman -Qg perl6 \
+    | awk '{print $2}' \
+    | xargs pacman -Ql \
+    | awk '{print $2}' \
+    | grep precomp))
+  for _pc in "${_precomp[@]}"; do
+    [[ -f "$pkgdir/$_pc" ]] && rm -f "$pkgdir/$_pc"
+  done
+
+  msg2 'Cleaning up pkgdir...'
+  find "$pkgdir" -type f -name "*.lock" -exec rm '{}' \;
+}