Initial import

1 files changed, 48 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..b167b0e0f296
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,48 @@
+# Maintainer: Andy Weidenbaum <archbaum@gmail.com>
+
+pkgname=perl6-file-temp
+pkgver=0.0.2
+pkgrel=1
+pkgdesc="Create temporary files"
+arch=('any')
+depends=('rakudo' 'perl6-file-directory-tree')
+checkdepends=('perl')
+makedepends=('alacryd' 'git')
+groups=('perl6')
+url="https://github.com/perlpilot/p6-File-Temp"
+license=('PerlArtistic')
+source=($pkgname-$pkgver::git+https://github.com/perlpilot/p6-File-Temp)
+sha256sums=('SKIP')
+
+check() {
+  cd "$srcdir/$pkgname-$pkgver"
+
+  msg2 'Running tests...'
+  PERL6LIB=lib prove -r -e perl6
+}
+
+package() {
+  cd "$srcdir/$pkgname-$pkgver"
+
+  msg2 'Installing documentation...'
+  install -Dm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
+
+  msg2 'Installing...'
+  install -dm 755 "$pkgdir/usr/share/perl6/vendor"
+  export RAKUDO_LOG_PRECOMP=1
+  export PERL6LIB="inst#$pkgdir/usr/share/perl6/vendor"
+  alacryd install
+
+  msg2 'Removing redundant precomp file dependencies...'
+  _precomp=($(pacman -Qg perl6 \
+    | awk '{print $2}' \
+    | xargs pacman -Ql \
+    | awk '{print $2}' \
+    | grep precomp))
+  for _pc in "${_precomp[@]}"; do
+    [[ -f "$pkgdir/$_pc" ]] && rm -f "$pkgdir/$_pc"
+  done
+
+  msg2 'Cleaning up pkgdir...'
+  find "$pkgdir" -type f -name "*.lock" -exec rm '{}' \;
+}