Initial commit

1 files changed, 34 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..5d5862f5fd1e
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,34 @@
+# Maintainer: Sematre <sematre at gmx dot de>
+pkgname=piknik-git
+pkgver=r228.00ee34c
+pkgrel=1
+pkgdesc="Copy/paste anything over the network."
+arch=('any')
+url="https://github.com/jedisct1/${pkgname%-git}"
+license=('BSD')
+provides=("${pkgname%-git}")
+conflicts=("${pkgname%-git}")
+makedepends=('go' 'git')
+source=("git+${url}")
+md5sums=('SKIP')
+
+pkgver() {
+  cd "${pkgname%-git}"
+  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+build() {
+  cd "${pkgname%-git}"
+  export CGO_CPPFLAGS="${CPPFLAGS}"
+  export CGO_CFLAGS="${CFLAGS}"
+  export CGO_CXXFLAGS="${CXXFLAGS}"
+  export CGO_LDFLAGS="${LDFLAGS}"
+  export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
+  go build
+}
+
+package() {
+  cd "${pkgname%-git}"
+  install -Dm 755 "${pkgname%-git}" -t "$pkgdir/usr/bin"
+  install -Dm 644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname%-git}/LICENSE"
+}