initial commit of polyml fixes from git repo, replaces polyml-svn

1 files changed, 42 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..eb8e9d8ddba3
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,42 @@
+# Maintainer: Ramana Kumar <ramana at member dot fsf dot org>
+pkgname=polyml-fixes-git
+pkgver=5.5.2r4.88a7241
+pkgrel=1
+pkgdesc="Poly/ML implementation of Standard ML (latest release + fixes)"
+arch=('i686' 'x86_64')
+url="http://polyml.org"
+license=('LGPL')
+groups=()
+depends=('gmp')
+makedepends=('git')
+provides=("${pkgname%-fixes-git}" "${pkgname%-fixes-git}-git")
+conflicts=("${pkgname%-fixes-git}" "${pkgname%-fixes-git}-git" "${pkgname%-fixes-git}-svn")
+replaces=("${pkgname%-fixes-git}-svn")
+backup=()
+options=('staticlibs')
+install=
+source=('git+https://github.com/polyml/polyml.git#branch=fixes-5.5.2')
+noextract=()
+md5sums=('SKIP')
+
+pkgver() {
+	cd "$srcdir/${pkgname%-fixes-git}"
+	printf "5.5.2r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+build() {
+	cd "$srcdir/${pkgname%-fixes-git}"
+	./configure --prefix=/usr --enable-shared
+	make
+  make compiler
+}
+
+check() {
+	cd "$srcdir/${pkgname%-fixes-git}"
+	make tests
+}
+
+package() {
+	cd "$srcdir/${pkgname%-fixes-git}"
+	make DESTDIR="$pkgdir/" install
+}