Switch build system to CMake

1 files changed, 16 insertions, 16 deletions

diff --git a/PKGBUILD b/PKGBUILD
index cbf6ae09a2d8..34503655c01c 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,39 +1,39 @@
 # Maintainer: Vaporeon <vaporeon@vaporeon.io>
 pkgname=punes-git
-pkgver=0.109.r1848.46ff1d83
+pkgver=0.109.r1893.2af242f7
 pkgrel=1
 pkgdesc="Nintendo Entertaiment System emulator"
 arch=('x86_64')
 url="https://github.com/punesemu/puNES"
 license=('GPL2')
 depends=('alsa-lib' 'desktop-file-utils' 'ffmpeg' 'hicolor-icon-theme' 'nvidia-cg-toolkit' 'libxrandr' 'qt5-base' 'qt5-svg')
-makedepends=('cmake' 'git' 'glu' 'qt5-tools')
+makedepends=('cmake' 'git' 'glu' 'ninja' 'qt5-tools')
 conflicts=('punes')
 provides=('punes')
-source=("git+https://github.com/punesemu/puNES.git")
+source=("punes::git+https://github.com/punesemu/puNES.git")
 md5sums=('SKIP')
 
 #breaks internal lib7zip
 options=('!buildflags')
 
 pkgver() {
-    cd puNES
-    printf "%s.r%s.%s" "$(git describe --abbrev=0 --tags | sed 's/v//')" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
-}
-
-prepare() {
-    cd "${srcdir}"/puNES
-    sed -e 's:^\tupdate-desktop-database.*$:\ttrue:' -i 'misc/Makefile.am'
+  cd "${pkgname%-git}"
+  printf "%s.r%s.%s" "$(git describe --abbrev=0 --tags | sed 's/v//')" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
 }
 
 build() {
-    cd "${srcdir}"/puNES
-    ./autogen.sh
-    ./configure --prefix=/usr
-    make
+  cmake -S "${pkgname%-git}" \
+    -G Ninja \
+    -B build \
+    -DENABLE_GIT_INFO=ON \
+    -DENABLE_OPENGL_CG=ON \
+    -DENABLE_QT6_LIBS=OFF \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_BUILD_TYPE=Release
+
+  cmake --build build --config Release
 }
 
 package() {
-    cd "${srcdir}"/puNES
-    make DESTDIR="${pkgdir}" install
+  DESTDIR="${pkgdir}" cmake --install build --config Release
 }