2.0.7.r2

1 files changed, 57 insertions, 40 deletions

diff --git a/PKGBUILD b/PKGBUILD
index f2ee065b7f09..1e6bd0138601 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,54 +1,71 @@
-# Maintainer: Ke Liu <spcter119@gmail.com>
+# Maintainer:
+# Contributor: Ke Liu <spcter119@gmail.com>
 
-pkgname=python-efb-wechat-slave-git
-_provide=${pkgname%-git}
-_name=${_provide#python-}
-pkgver=r227.540b7a7
+_module="efb-wechat-slave"
+_pkgname="python-$_module"
+pkgname="$_pkgname-git"
+pkgver=2.0.7.r2.g80dadf2
 pkgrel=1
-pkgdesc='EFB WeChat Slave, a channel for EH Forwarder Bot.'
-arch=('any')
+pkgdesc='EFB WeChat Slave, a channel for EH Forwarder Bot'
 url='https://github.com/blueset/efb-wechat-slave'
-license=('AGPL-3')
-groups=('efb')
-depends=(
-	'python-ehforwarderbot'
-	'python-itchat'
-	'python-magic-ahupp'
-	'python-pillow'
-	'libwebp'
-	'python-pyqrcode'
-	'python-yaml'
-	'python-requests'
-	'python-typing_extensions'
-	'python-bullet'
-	'python-cjkwrap')
+license=('AGPL-3.0-or-later')
+arch=('any')
+
+depends=('python')
 makedepends=(
-	'git'
-	'python-setuptools')
-provides=($_provide)
-conflicts=($_provide)
-source=("$_provide"::"git+${url}.git")
-md5sums=('SKIP')
+  'git'
+  'python-build'
+  'python-installer'
+  'python-setuptools'
+  'python-wheel'
+)
+
+provides=("$_pkgname")
+conflicts=("$_pkgname")
+
+_pkgsrc="$_pkgname"
+source=("$_pkgsrc"::"git+$url.git")
+sha256sums=('SKIP')
 
 pkgver() {
-	cd "$srcdir/$_provide"
-	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+  cd "$_pkgsrc"
+  git describe --long --tags --exclude='*[a-zA-Z][a-zA-Z]*' \
+    | sed -E 's/^[^0-9]*//;s/([^-]*-g)/r\1/;s/-/./g'
 }
 
 build() {
-	cd "$srcdir/$_provide"
-	python setup.py clean --all
-	python setup.py build
-	cd "build/lib/${_name//-/_}/locale/"
-	rm -rf ach_UG
-	for _locale in $(ls); do
-		(cd "$_locale/LC_MESSAGES/"; msgfmt "${_name//-/_}.po" -o "${_name//-/_}.mo")
-	done
+  cd "$_pkgsrc"
+  python -m build --wheel --no-isolation
+
+  cd "build/lib/${_module//-/_}/locale/"
+  for _locale in [a-z][a-z]*; do
+    (cd "$_locale/LC_MESSAGES/"; msgfmt "${_module//-/_}.po" -o "${_module//-/_}.mo")
+  done
 }
 
 package() {
-	cd "$srcdir/$_provide"
-	python setup.py install --root="$pkgdir/" --optimize=1 --skip-build
-	install -Dm644 "$srcdir/$_provide/LICENSE.md" "$pkgdir/usr/share/licenses/$_provide/LICENSE.md"
+  depends+=(
+    'bpython'
+    'ipython'
+    'python-cjkwrap'
+    'python-future'
+    'python-httplib2'
+    'python-magic'
+    'python-pillow'
+    'python-pyqrcode'
+    'python-requests'
+    'python-ruamel-yaml'
+    'python-typing_extensions'
+    'python-wxpython'
+    'python-yaml'
+
+    # AUR
+    'python-bullet'
+    'python-ehforwarderbot'
+    'python-itchat'
+  )
+
+  cd "$_pkgsrc"
+  python -m installer --destdir="$pkgdir" dist/*.whl
 }