Version 0.4.0

1 files changed, 23 insertions, 29 deletions

diff --git a/PKGBUILD b/PKGBUILD
index 95ab8d824830..d97a7288f3d0 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,43 +1,37 @@
-# Contributor: Lex Black <autumn-wind@web.de>
+# Maintainer: a821
+# Contributor: Lex Black <autumn-wind - web - de>
 # Contributor: Jonathan Kotta <jpkotta at gmail dot com>
 
-_name=ipython-sql
-pkgbase=python-ipython-sql
-pkgname=(python-ipython-sql python2-ipython-sql)
-pkgver=0.3.9
+pkgname=python-ipython-sql
+pkgver=0.4.0
 pkgrel=1
-pkgdesc="Issue SQL commands from IPython."
+pkgdesc="RDBMS access via IPython"
 arch=('any')
 url="https://pypi.python.org/pypi/ipython-sql"
-license=('custom:PYTHON')
-makedepends=('ipython' 'python-sqlalchemy' 'python-prettytable' 'python-sqlparse')
-makedepends+=('ipython2' 'python2-sqlalchemy' 'python2-prettytable' 'python2-sqlparse')
-source=(https://files.pythonhosted.org/packages/source/${_name::1}/$_name/$_name-$pkgver.tar.gz)
-md5sums=('69407492ac7fcb92520e10d24b3b3194')
-
+license=('MIT')
+depends=('ipython' 'python-sqlalchemy' 'python-prettytable' 'python-sqlparse' 'python-six')
+source=("https://files.pythonhosted.org/packages/source/i/${pkgname#python-}/${pkgname#python-}-$pkgver.tar.gz")
+sha256sums=('3e888e59bf57277cbd6f383cb232858b2d7c71219e5749257128f16d9857e46c')
+optdepends=(
+    'python-pandas: DataFrame support'
+    'python-pymysql: connect to MySQL database'
+    'python-psycopg2: connect to PostgreSQL database')
 
 prepare() {
-  cp -a ${_name}-${pkgver}{,-python2}
+    # fix missing file
+    cd "${pkgname#python-}-${pkgver}"
+    test -f NEWS.rst || touch NEWS.rst
 }
 
 build() {
-  cd "${_name}-${pkgver}"
-  python setup.py build
-
-  cd "${srcdir}/${_name}-${pkgver}-python2"
-  python2 setup.py build
+    cd "${pkgname#python-}-${pkgver}"
+    python setup.py build
 }
 
-package_python-ipython-sql() {
-  depends=('ipython' 'python-sqlalchemy' 'python-prettytable' 'python-sqlparse')
-
-  cd "${_name}-${pkgver}"
-  python setup.py install --prefix=/usr --root="${pkgdir}" --optimize=1 --skip-build
+package() {
+    cd "${pkgname#python-}-${pkgver}"
+    python setup.py install --prefix=/usr --root="${pkgdir}" --optimize=1 --skip-build
+    install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/$pkgname/LICENSE"
 }
 
-package_python2-ipython-sql() {
-  depends=('ipython2' 'python2-sqlalchemy' 'python2-prettytable' 'python2-sqlparse')
-
-  cd "${_name}-${pkgver}-python2"
-  python2 setup.py install --prefix=/usr --root="${pkgdir}" --optimize=1 --skip-build
-}
+# vim: set ts=4 sw=4 et: