Fix build

1 files changed, 26 insertions, 11 deletions

diff --git a/PKGBUILD b/PKGBUILD
index 19a6491a8d95..d5cac8338bd0 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -2,7 +2,7 @@
 _pkgname=qiskit-aer
 pkgname=python-${_pkgname}
 pkgver=0.10.3
-pkgrel=1
+pkgrel=2
 pkgdesc="A high performance simulator for quantum circuits that includes noise models"
 arch=('x86_64')
 url="https://github.com/Qiskit/qiskit-aer"
@@ -16,34 +16,49 @@ depends=(
     'python-scipy'
 )
 optdepends=(
-    'cuda: Parallelization with CUDA (NVIDIA)'
-    'intel-tbb: Parallelization with Intel TBB'
-    'openmp: Parallelization with OpenMP'
-    'thrust: Parallelization (GPU/CPU) support'
-    'python-dask: Parallel computing'
+    'openblas: optimized BLAS library'
+    'openmp: parallelization with OpenMP'
+    'python-dask: parallel computing with task scheduling'
+    'python-distributed: distributed task scheduler for Dask'
 )
 makedepends=(
     'cmake'
+    'ninja'
     'pybind11'
-    'python-pip'
+    'python-build'
+    'python-installer'
     'python-scikit-build'
     'python-setuptools'
+    'python-wheel'
     'spdlog'
 )
-source=("${_pkgname}-${pkgver}.tar.gz::https://github.com/Qiskit/${_pkgname}/archive/${pkgver}.tar.gz")
+source=(
+    "${_pkgname}-${pkgver}.tar.gz::https://github.com/Qiskit/${_pkgname}/archive/${pkgver}.tar.gz"
+    "fix.patch"
+)
+
+sha256sums=(
+    'debc146f4c05c4187cda24bcf9d690ab9845d266c706d9685c145e6795e11443'
+    'c847b08cf47e384bfec3c75aa38cc9b03f9c9976b40956f2b332a946f1a2c124'
+)
 
-sha256sums=('debc146f4c05c4187cda24bcf9d690ab9845d266c706d9685c145e6795e11443')
+prepare() {
+    cd "${srcdir}/${_pkgname}-${pkgver}"
+    patch --forward --strip=1 --input="${srcdir}/fix.patch"
+}
 
 build() {
     cd "${srcdir}/${_pkgname}-${pkgver}"
-    DISABLE_CONAN=ON python setup.py build
+    DISABLE_CONAN=ON python -m build --wheel --no-isolation
 }
 
 package() {
     cd "${srcdir}/${_pkgname}-${pkgver}"
-    python setup.py install --root="${pkgdir}/" --optimize=1 --skip-build
+    python -m installer --destdir="$pkgdir" dist/*.whl
 
     # This deletes all folders except /usr/lib/python3.10/site-packages/qiskit/
     # See https://github.com/Qiskit/qiskit-aer/issues/1457
     find "${pkgdir}/usr" -mindepth 1 -maxdepth 1 -not -name lib -exec rm -rf '{}' \;
+
+    install -D -m644 LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
 }