Convert TensorFlow models to ONNX

1 files changed, 31 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..5aec6b8f9160
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,31 @@
+# Maintainer: Chih-Hsuan Yen <yan12125@archlinux.org>
+
+pkgname=python-tf2onnx
+pkgver=1.6.3
+pkgrel=1
+pkgdesc='Convert TensorFlow models to ONNX'
+arch=(any)
+url='https://github.com/onnx/tensorflow-onnx'
+license=(MIT)
+depends=(python python-tensorflow python-numpy python-onnx python-requests python-six)
+makedepends=(python-setuptools)
+checkdepends=(python-pytest python-graphviz python-parameterized python-yaml python-onnxruntime)
+source=("https://github.com/onnx/tensorflow-onnx/archive/v$pkgver/tf2onnx-v$pkgver.tar.gz")
+sha256sums=('82ab1ed80b26e66b5b25dbee713be6ae3a916092db1fe088bc94634158d90cfa')
+
+build() {
+  cd tensorflow-onnx-$pkgver
+  python setup.py build
+}
+
+check() {
+  cd tensorflow-onnx-$pkgver
+  # The default opset is 8, in which lots of tests are skipped
+  PYTHONPATH="$PWD" TF2ONNX_TEST_OPSET=12 pytest -rs -c /dev/null tests
+}
+
+package() {
+  cd tensorflow-onnx-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+  install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
+}