first commit

1 files changed, 46 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..84d4b8404d65
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,46 @@
+# Maintainer: Butui Hu <hot123tea123@gmail.com>
+
+pkgname=python-torchio
+_pkgname=torchio
+pkgver=0.13.14
+pkgrel=1
+pkgdesc='Tools for medical image processing in deep learning and PyTorch'
+arch=(any)
+url='https://github.com/fepegar/torchio'
+license=(MIT)
+depends=(
+  'python-click'
+  'python-nibabel'
+  'python-numpy'
+  'python-pytorch'
+  'python-scipy'
+  'python-simpleitk'
+  'python-torchvision'
+  'python-tqdm'
+)
+makedepends=(
+  'python-setuptools'
+)
+checkdepends=(
+  'python-pytest'    
+)
+
+source=("${pkgname}-${pkgver}.tar.gz::https://github.com/fepegar/torchio/archive/v${pkgver}.tar.gz")
+sha512sums=('4ff9abe056e6d111fca19a1e55696a924456ed55245ae204dafd5464379ea3283c33493b2efbc61b58be97a8d46fe4071e8584d00b4f6f01f26bb2ae23b2b212')
+
+build() {
+  cd "${_pkgname}-${pkgver}"
+  python setup.py build
+}
+
+check() {
+  cd "${_pkgname}-${pkgver}"
+  pytest -v .
+}
+
+package() {
+  cd "${_pkgname}-${pkgver}"
+  python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
+  install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
+}
+# vim:set ts=2 sw=2 et: