Initial import

1 files changed, 41 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..bedd7b8bcf9a
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,41 @@
+# Maintainer: Andy Weidenbaum <archbaum@gmail.com>
+
+pkgname=python2-snakebite
+pkgver=2.5.4
+pkgrel=1
+pkgdesc="Pure Python HDFS client"
+arch=('any')
+depends=('python2' 'python2-protobuf')
+makedepends=('python2-setuptools')
+url="https://github.com/spotify/snakebite"
+license=('Apache')
+options=(!emptydirs)
+source=(https://pypi.python.org/packages/source/s/${pkgname#python2-}/${pkgname#python2-}-$pkgver.tar.gz)
+md5sums=('6ee92be030f5bea0042754b9f1c91bb4')
+sha256sums=('7fc93a2abc74ebc94fa5bb104685fec2bdec66c21602b476335fe696c843506b')
+provides=('python2-snakebite' 'snakebite')
+conflicts=('snakebite')
+
+build() {
+  cd "$srcdir/${pkgname#python2-}-$pkgver"
+
+  msg 'Building...'
+  python2 setup.py build
+}
+
+package() {
+  cd "$srcdir/${pkgname#python2-}-$pkgver"
+
+  msg 'Installing...'
+  python2 setup.py install --root="$pkgdir" --optimize=1
+
+  msg 'Fixing LICENSE placement...'
+  install -dm 755 "$pkgdir/usr/share/licenses/$pkgname"
+  mv "$pkgdir/usr/LICENSE" "$pkgdir/usr/share/licenses/$pkgname"
+
+  msg 'Fixing bash-completion placement...'
+  install -dm 755 "$pkgdir/usr/share/bash-completion/completions"
+  mv "$pkgdir/usr/etc/bash_completion.d/snakebite-completion.bash" \
+    "$pkgdir/usr/share/bash-completion/completions/snakebite"
+  rm -rf "$pkgdir/usr/etc"
+}