Initial import

1 files changed, 44 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..10b026e50d02
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,44 @@
+# Maintainer: Pier Luigi Fiorini <pierluigi.fiorini@gmail.com>
+
+pkgname=qt5-gsettings-git
+pkgver=20170506.0213d57
+pkgrel=1
+pkgdesc="Qt-style wrapper for GSettings"
+arch=('i686' 'x86_64' 'armv6h' 'armv7h')
+url='https://liri.io'
+license=('LGPL3')
+depends=('qt5-declarative')
+makedepends=('git' 'qbs')
+conflicts=('qt5-gsettings')
+replaces=('qt5-gsettings')
+provides=('qt5-gsettings')
+groups=('liri-git')
+
+_gitroot="git://github.com/lirios/qtgsettings.git"
+_gitbranch=develop
+_gitname=qtgsettings
+source=(${_gitname}::${_gitroot}#branch=${_gitbranch})
+md5sums=('SKIP')
+
+pkgver() {
+	cd ${srcdir}/${_gitname}
+	echo "$(git log -1 --format="%cd" --date=short | tr -d '-').$(git log -1 --format="%h")"
+}
+
+prepare() {
+	cd ${srcdir}/${_gitname}
+	git submodule update --init
+}
+
+build() {
+	cd ${srcdir}/${_gitname}
+	qbs setup-toolchains --type gcc /usr/bin/g++ gcc
+	qbs setup-qt /usr/bin/qmake-qt5 qt5
+	qbs config profiles.qt5.baseProfile gcc
+	qbs build --no-install -d build profile:qt5 qbs.installRoot:/usr lirideployment.qmlDir:lib/qt/qml
+}
+
+package() {
+	cd ${srcdir}/${_gitname}
+	qbs install -d build --no-build -v --install-root $pkgdir/usr profile:qt5
+}