Version 1.0.0

1 files changed, 52 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..fe1f41bece5f
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,52 @@
+# Maintainer: Pekka Ristola <pekkarr [at] protonmail [dot] com>
+
+_pkgname=hicVennDiagram
+_pkgver=1.0.0
+pkgname=r-${_pkgname,,}
+pkgver=${_pkgver//-/.}
+pkgrel=1
+pkgdesc="Venn Diagram for genomic interaction data"
+arch=(any)
+url="https://bioconductor.org/packages/${_pkgname}"
+license=(GPL3)
+depends=(
+  r-complexupset
+  r-eulerr
+  r-ggplot2
+  r-htmlwidgets
+  r-interactionset
+  r-reshape2
+  r-rtracklayer
+  r-s4vectors
+  r-svglite
+)
+checkdepends=(
+  r-genomicranges
+  r-testthat
+)
+optdepends=(
+  r-biocstyle
+  r-chippeakanno
+  r-genomicranges
+  r-knitr
+  r-rmarkdown
+  r-testthat
+)
+source=("https://bioconductor.org/packages/release/bioc/src/contrib/${_pkgname}_${_pkgver}.tar.gz")
+md5sums=('11577b64cc67b69e4b9d712a76cd3310')
+sha256sums=('0b172ec2b21d62be894deb7a67794d6f954b900f0eadbbcd03b0f2fbb506dc75')
+
+build() {
+  mkdir -p build
+  R CMD INSTALL "$_pkgname" -l build
+}
+
+check() {
+  cd "$_pkgname/tests"
+  R_LIBS="$srcdir/build" NOT_CRAN=true Rscript --vanilla runTests.R
+}
+
+package() {
+  install -d "$pkgdir/usr/lib/R/library"
+  cp -a --no-preserve=ownership "build/$_pkgname" "$pkgdir/usr/lib/R/library"
+}