Version 1.6.0

1 files changed, 50 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..8fdde111f1bd
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,50 @@
+# Maintainer: Pekka Ristola <pekkarr [at] protonmail [dot] com>
+
+_pkgname=lineagespot
+_pkgver=1.6.0
+pkgname=r-${_pkgname,,}
+pkgver=${_pkgver//-/.}
+pkgrel=1
+pkgdesc="Detection of SARS-CoV-2 lineages in wastewater samples using next-generation sequencing"
+arch=(any)
+url="https://bioconductor.org/packages/${_pkgname}"
+license=(MIT)
+depends=(
+  r-data.table
+  r-httr
+  r-matrixgenerics
+  r-stringr
+  r-summarizedexperiment
+  r-variantannotation
+)
+checkdepends=(
+  r-testthat
+)
+optdepends=(
+  r-biocstyle
+  r-knitr
+  r-refmanager
+  r-rmarkdown
+  r-testthat
+)
+source=("https://bioconductor.org/packages/release/bioc/src/contrib/${_pkgname}_${_pkgver}.tar.gz")
+md5sums=('7a06bfea8fdf81ea88ebe7f4478607f6')
+sha256sums=('2606c8052dc41b4d9fe8c1b6c6ae075c8b06d2f2b395c822f73abca4e0217c7b')
+
+build() {
+  mkdir -p build
+  R CMD INSTALL "$_pkgname" -l build
+}
+
+check() {
+  cd "$_pkgname/tests"
+  R_LIBS="$srcdir/build" NOT_CRAN=true Rscript --vanilla testthat.R
+}
+
+package() {
+  install -d "$pkgdir/usr/lib/R/library"
+  cp -a --no-preserve=ownership "build/$_pkgname" "$pkgdir/usr/lib/R/library"
+
+  install -d "$pkgdir/usr/share/licenses/$pkgname"
+  ln -s "/usr/lib/R/library/$_pkgname/LICENSE" "$pkgdir/usr/share/licenses/$pkgname"
+}