Build against system cctz and add check() function

1 files changed, 36 insertions, 7 deletions

diff --git a/PKGBUILD b/PKGBUILD
index b737249eca34..198bdf51ebbb 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,4 +1,5 @@
-# Maintainer: Viktor Drobot (aka dviktor) linux776 [at] gmail [dot] com
+# Maintainer: Pekka Ristola <pekkarr [at] protonmail [dot] com>
+# Contributor: Viktor Drobot (aka dviktor) linux776 [at] gmail [dot] com
 # Contributor: Clint Valentine <valentine.clint@gmail.com>
 # Contributor: wagnerflo <florian@wagner-flo.net>
 
@@ -6,23 +7,51 @@ _cranname=lubridate
 _cranver=1.8.0
 pkgname=r-${_cranname,,}
 pkgver=${_cranver//[:-]/.}
-pkgrel=1
+pkgrel=2
 pkgdesc="Make Dealing with Dates a Little Easier"
 arch=(i686 x86_64)
 url="https://cran.r-project.org/package=${_cranname}"
-license=(GPL2 GPL3)
-depends=('r>=3.2' r-generics 'r-cpp11>=0.2.7')
-optdepends=(r-covr r-knitr r-testthat r-vctrs r-rmarkdown)
+license=(GPL)
+depends=(cctz r-generics)
+makedepends=(r-cpp11)
+checkdepends=(r-testthat)
+optdepends=(
+    r-covr
+    r-knitr
+    r-testthat
+    r-vctrs
+    r-rmarkdown
+)
 source=("https://cran.r-project.org/src/contrib/${_cranname}_${_cranver}.tar.gz")
 sha256sums=('87d66efdb1f3d680db381d7e40a202d35645865a0542e2f270ef008a19002ba5')
 
+prepare() {
+  cd "${_cranname}"
+
+  # skip test that requires a French locale
+  sed -i '/"parsing months with dots works in French linux locale"/a skip("Requires a French locale")' \
+      tests/testthat/test-parsers.R
+
+  # build against system cctz
+  sed -i -e 's|-I. -I./cctz/src/|-I.|' \
+      -e 's/$(SHLIB): libcctz.a/$(SHLIB):/' \
+      -e '/$(OBJECTS): libcctz.a/d' \
+      src/Makevars
+}
+
 build() {
-  R CMD INSTALL ${_cranname}_${_cranver}.tar.gz -l "${srcdir}"
+  mkdir -p build
+  R CMD INSTALL "${_cranname}" -l "${srcdir}/build"
+}
+
+check() {
+  cd "${_cranname}/tests"
+  R_LIBS="${srcdir}/build" NOT_CRAN=true Rscript --vanilla testthat.R
 }
 
 package() {
   install -dm0755 "${pkgdir}/usr/lib/R/library"
 
-  cp -a --no-preserve=ownership "${_cranname}" "${pkgdir}/usr/lib/R/library"
+  cp -a --no-preserve=ownership "build/${_cranname}" "${pkgdir}/usr/lib/R/library"
 }