Version 1.6.0

1 files changed, 43 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..cd500cfef853
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,43 @@
+# Maintainer: Pekka Ristola <pekkarr [at] protonmail [dot] com>
+
+_pkgname=RAREsim
+_pkgver=1.6.0
+pkgname=r-${_pkgname,,}
+pkgver=${_pkgver//-/.}
+pkgrel=1
+pkgdesc="Simulation of Rare Variant Genetic Data"
+arch=(any)
+url="https://bioconductor.org/packages/${_pkgname}"
+license=(GPL3)
+depends=(
+  r-nloptr
+)
+checkdepends=(
+  r-testthat
+)
+optdepends=(
+  r-biocstyle
+  r-ggplot2
+  r-knitr
+  r-markdown
+  r-rmarkdown
+  r-testthat
+)
+source=("https://bioconductor.org/packages/release/bioc/src/contrib/${_pkgname}_${_pkgver}.tar.gz")
+md5sums=('6ec5b86f348e2d4ffb365da80651041e')
+sha256sums=('8fb2a823bf1b18ea70eb886ed8726c47896ac240156499e90943fd36f1de213f')
+
+build() {
+  mkdir -p build
+  R CMD INSTALL "$_pkgname" -l build
+}
+
+check() {
+  cd "$_pkgname/tests"
+  R_LIBS="$srcdir/build" NOT_CRAN=true Rscript --vanilla testthat.R
+}
+
+package() {
+  install -d "$pkgdir/usr/lib/R/library"
+  cp -a --no-preserve=ownership "build/$_pkgname" "$pkgdir/usr/lib/R/library"
+}