Initial PKGBUILD

1 files changed, 51 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..833db05b8763
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,51 @@
+# Maintainer: Doug Newgard <scimmia22 at outlook dot com>
+
+_pkgname=rage
+pkgname=$_pkgname-git
+pkgver=0.1.0.r5.f2cb079
+pkgrel=1
+pkgdesc="Video Player based on EFL"
+arch=('i686' 'x86_64')
+url="http://www.enlightenment.org"
+license=('BSD')
+depends=('elementary>=1.8.99' 'desktop-file-utils')
+makedepends=('git')
+provides=("$_pkgname=$pkgver")
+conflicts=("$_pkgname")
+install=$_pkgname.install
+source=("git://git.enlightenment.org/apps/$_pkgname.git")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "$srcdir/$_pkgname"
+
+  local v_ver=$(awk -F , '/^AC_INIT/ {gsub(/[\[\] -]/, ""); print $2}' configure.ac)
+
+  printf "$v_ver.r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
+}
+
+build() {
+  cd "$srcdir/$_pkgname"
+
+  export CFLAGS="$CFLAGS -fvisibility=hidden"
+
+  ./autogen.sh \
+    --prefix=/usr
+
+  make
+}
+
+package() {
+  cd "$srcdir/$_pkgname"
+
+  make -j1 DESTDIR="$pkgdir" install
+
+# install text files
+  install -Dm644 ChangeLog "$pkgdir/usr/share/doc/$_pkgname/ChangeLog"
+  install -Dm644 NEWS "$pkgdir/usr/share/doc/$_pkgname/NEWS"
+  install -Dm644 README "$pkgdir/usr/share/doc/$_pkgname/README"
+
+# install license files
+  install -Dm644 AUTHORS "$pkgdir/usr/share/licenses/$pkgname/AUTHORS"
+  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
+}