revision

1 files changed, 86 insertions, 108 deletions

diff --git a/PKGBUILD b/PKGBUILD
index d423412d2c6f..098987b0169f 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,128 +1,106 @@
-# Maintainer: Martin Sandsmark <martin.sandsmark@kde.org>
+# Maintainer: Fabio 'Lolix' Loli <fabio.loli@disroot.org> -> https://github.com/FabioLolix
+# Contributor: Martin Sandsmark <martin.sandsmark@kde.org>
 
 pkgname=redasm-git
-pkgver=r1597.5f723db
+pkgver=3.0.0.beta5.r32.g6e8bbae
 pkgrel=1
-url='https://github.com/REDasmOrg/REDasm'
-arch=('i686' 'x86_64')
-pkgdesc='The OpenSource Disassembler'
-license=('GPL3')
-depends=('qt5-base' 'tbb')
-makedepends=('git' 'patchelf')
+url="https://github.com/REDasmOrg/REDasm"
+arch=(i686 x86_64)
+pkgdesc="The OpenSource Disassembler"
+license=(GPL3)
+depends=(qt6-base)
+makedepends=(git cmake patchelf qt6-tools)
 conflicts=(redasm)
 provides=(redasm)
-
-# TODO: see if we can use system libraries
-source=(
-    'git+https://github.com/REDasmOrg/REDasm.git'
-
-    'git+https://github.com/REDasmOrg/REDasm-Library.git'
-    'git+https://github.com/REDasmOrg/REDasm-Plugins.git'
-    'git+https://github.com/REDasmOrg/REDasm-Loaders.git'
-    'git+https://github.com/REDasmOrg/REDasm-Assemblers.git'
-
-    'git+https://github.com/Dax89/QHexView.git'
-
-    'git+https://github.com/aquynh/capstone.git'
-
-    'git+https://github.com/taocpp/json.git'
-    'git+https://github.com/taocpp/PEGTL.git'
-
-    'git+https://github.com/zyantific/zydis.git'
-    'git+https://github.com/zyantific/zycore-c.git'
-
-    "plugin-path.patch"
-    )
-
-md5sums=(
-    'SKIP'
-
-    'SKIP'
-    'SKIP'
-    'SKIP'
-    'SKIP'
-
-    'SKIP'
-
-    'SKIP'
-
-    'SKIP'
-    'SKIP'
-
-    'SKIP'
-    'SKIP'
-
-    'SKIP'
+source=("git+https://github.com/REDasmOrg/REDasm.git"
+        "git+https://github.com/REDasmOrg/REDasm-Library.git"
+        "git+https://github.com/REDasmOrg/REDasm-Plugins.git"
+        "git+https://github.com/REDasmOrg/REDasm-Loaders.git"
+        "git+https://github.com/REDasmOrg/REDasm-Assemblers.git"
+        "git+https://github.com/REDasmOrg/REDasm-Database.git"
+        "git+https://github.com/Dax89/QHexView.git"
+        #"git+https://github.com/aquynh/capstone.git"
+        "git+https://github.com/capstone-engine/capstone.git"
+        "git+https://github.com/taocpp/json.git"
+        "git+https://github.com/taocpp/PEGTL.git"
+        "git+https://github.com/zyantific/zydis.git"
+        "git+https://github.com/zyantific/zycore-c.git"
 )
+sha256sums=('SKIP'
+            'SKIP'
+            'SKIP'
+            'SKIP'
+            'SKIP'
+            'SKIP'
+            'SKIP'
+            'SKIP'
+            'SKIP'
+            'SKIP'
+            'SKIP'
+            'SKIP')
 
 pkgver() {
   cd REDasm
-  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
 }
 
 prepare() {
-    # We use patchelf instead
-    #sed -i -e '/set\(CMAKE_SKIP_BUILD_RPATH TRUE\)/d' "$srcdir"/REDasm-Library/rdapi/FindREDasm.cmake
-    #sed -i -e 's/PRIVATE LibREDasm/PUBLIC LibREDasm/' "$srcdir"/REDasm-Library/rdapi/FindREDasm.cmake
-
-    cd REDasm
-    git apply "$srcdir"/plugin-path.patch
-    git submodule init
-    git config submodule.LibREDasm.url "$srcdir/REDasm-Library"
-    git config submodule.QHexView.url "$srcdir/QHexView"
-    git config submodule.submodules/plugins.url "$srcdir/REDasm-Plugins"
-    git config submodule.submodules/loaders.url "$srcdir/REDasm-Loaders"
-    git config submodule.submodules/assemblers.url "$srcdir/REDasm-Assemblers"
-    git submodule update
-
-    cd LibREDasm
-    git submodule init
-    git config submodule.rdcore/libs/taojson.url "$srcdir/json"
-    git submodule update
-
-    cd rdcore/libs/taojson
-    git submodule init
-    git config submodule.external/PEGTL.url "$srcdir/PEGTL"
-    git submodule update
-
-    cd "$srcdir"/REDasm/submodules/assemblers
-    git submodule init
-    git config submodule.x86/zydis.url "$srcdir/zydis"
-    git config submodule.arm64/capstone.url "$srcdir/capstone"
-    git submodule update
-
-    cd x86/zydis
-    git submodule init
-    git config submodule.dependencies/zycore.url "$srcdir/zycore-c"
-    git submodule update
+  cd REDasm
+  git submodule init
+  git config submodule.LibREDasm.url "${srcdir}/REDasm-Library"
+  git config submodule.submodules/plugins.url "${srcdir}/REDasm-Plugins"
+  git config submodule.submodules/loaders.url "${srcdir}/REDasm-Loaders"
+  git config submodule.submodules/assemblers.url "${srcdir}/REDasm-Assemblers"
+  git config submodule.submodules/database.url "${srcdir}/REDasm-Database"
+  git config submodule.libs/qhexview.url "${srcdir}/QHexView"
+  git -c protocol.file.allow=always submodule update
+
+  cd LibREDasm
+  git submodule init
+  git config submodule.rdcore/libs/taojson.url "${srcdir}/json"
+  git -c protocol.file.allow=always submodule update
+
+  cd rdcore/libs/taojson
+  git submodule init
+  git config submodule.external/PEGTL.url "${srcdir}/PEGTL"
+  git -c protocol.file.allow=always submodule update
+
+  cd "${srcdir}"/REDasm/submodules/assemblers
+  git submodule init
+  git config submodule.x86/zydis.url "${srcdir}/zydis"
+  git config submodule.capstonebundle/capstone.url "${srcdir}/capstone"
+  git -c protocol.file.allow=always submodule update
+
+  cd x86/zydis
+  git submodule init
+  git config submodule.dependencies/zycore.url "${srcdir}/zycore-c"
+  git -c protocol.file.allow=always submodule update
 }
 
 build() {
-    mkdir -p build
-    cd build
-    cmake ../REDasm \
-        -DCMAKE_INSTALL_PREFIX=/usr
+  cmake -B build -S "REDasm" -Wno-dev \
+    -DCMAKE_BUILD_TYPE=None \
+    -DCMAKE_INSTALL_PREFIX=/usr
 
-    make VERBOSE=1
+  cmake --build build
 }
 
 package() {
-    cd ${srcdir}/build
-    patchelf --set-rpath /usr/lib REDasm
-    install -D -m755 REDasm ${pkgdir}/usr/bin/REDasm
-    install -D -m755 LibREDasm.so ${pkgdir}/usr/lib/LibREDasm.so
-    install -d -m755 ${pkgdir}/usr/lib/redasm/
-
-    install -m755 ./plugins/loaders/esp/esp.so ${pkgdir}/usr/lib/redasm/
-    install -m755 ./plugins/loaders/chip8/chip8.so ${pkgdir}/usr/lib/redasm/
-    install -m755 ./plugins/loaders/psx/psx.so ${pkgdir}/usr/lib/redasm/
-    install -m755 ./plugins/loaders/elf/elf.so ${pkgdir}/usr/lib/redasm/
-    install -m755 ./plugins/loaders/pe/pe.so ${pkgdir}/usr/lib/redasm/
-    install -m755 ./plugins/assemblers/x86/x86.so ${pkgdir}/usr/lib/redasm/
-    install -m755 ./plugins/assemblers/mips/mips.so ${pkgdir}/usr/lib/redasm/
-    install -m755 ./plugins/plugins/compiler/compiler.so ${pkgdir}/usr/lib/redasm/
-
-    cd ${srcdir}/REDasm
-    install -D -m644 README.md ${pkgdir}/usr/share/doc/${pkgname}/README
-    install -D -m644 LICENSE ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
+  cd build
+  patchelf --set-rpath /usr/lib REDasm
+  install -D -m755 REDasm ${pkgdir}/usr/bin/REDasm
+  install -D -m755 LibREDasm/LibREDasm.so ${pkgdir}/usr/lib/LibREDasm.so
+  install -d -m755 ${pkgdir}/usr/lib/redasm/
+
+  install -m755 ./plugins/loaders/esp/esp.so ${pkgdir}/usr/lib/redasm/
+  install -m755 ./plugins/loaders/chip8/chip8.so ${pkgdir}/usr/lib/redasm/
+  install -m755 ./plugins/loaders/psx/psx.so ${pkgdir}/usr/lib/redasm/
+  install -m755 ./plugins/loaders/elf/elf.so ${pkgdir}/usr/lib/redasm/
+  install -m755 ./plugins/loaders/pe/pe.so ${pkgdir}/usr/lib/redasm/
+  install -m755 ./plugins/assemblers/x86/x86.so ${pkgdir}/usr/lib/redasm/
+  install -m755 ./plugins/assemblers/mips/mips.so ${pkgdir}/usr/lib/redasm/
+  install -m755 ./plugins/plugins/compiler/compiler.so ${pkgdir}/usr/lib/redasm/
+
+  install -D -m644 "${srcdir}"/REDasm/README.md ${pkgdir}/usr/share/doc/${pkgname}/README
+  install -D -m644 "${srcdir}"/REDasm/LICENSE ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
 }