initial

1 files changed, 43 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..63d6900d26ff
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,43 @@
+###PKGBUILD was last modified on September 18, 2022 at 05:49 PM EDT by bms###
+# Maintainer: Ben Sutter <benjaminsutter@outlook.com>
+pkgname=remake-git
+pkgver=r3131.7619a012
+pkgrel=1
+pkgdesc="Enhanced GNU Make - tracing, error reporting, debugging, profiling and more"
+arch=('x86_64' 'aarch64')
+url="http://bashdb.sourceforge.net/remake/"
+license=('GPL3')
+provides=("remake=$pkgver")
+conflicts=('remake')
+depends=('glibc' 'guile')
+makedepends=('git' 'patch')
+source=("${pkgname%-git}::git+https://github.com/rocky/remake.git")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "${pkgname%-git}"
+  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+prepare() {
+  cd "${pkgname%-git}"
+  autoreconf -fi
+  ./configure --disable-nls --with-guile --prefix=/usr
+  (cd doc && make stamp-1 stamp-vti)
+}
+
+build() {
+  cd "${pkgname%-git}"
+  make
+}
+
+check() {
+  cd "${pkgname%-git}"
+  make check
+}
+
+package() {
+  cd "${pkgname%-git}"
+  make DESTDIR="$pkgdir" install
+  rm "$pkgdir"/usr/share/info/make.info{,-1,-2}
+}