0.6.5-1 (initial packaging)

Forked off from the pacman-hacks PKGBUILD. The history could not be
retained, as the AUR doesn't like commits that don't contain a .SRCINFO.

1 files changed, 38 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..8246ba2854cf
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,38 @@
+# Maintainer: Tinu Weber <http://ayekat.ch>
+
+pkgname=remakepkg
+pkgver=0.6.5
+pkgrel=1
+arch=(any)
+
+pkgdesc='Apply changes to pacman packages'
+url='https://gitlab.com/ayekat/pacman-hacks'
+license=(GPL3)
+
+depends=(coreutils)
+makedepends=(asciidoc git)
+
+source=("git+https://gitlab.com/ayekat/pacman-hacks.git#tag=v$pkgver"
+        'diffrepo.hook.example')
+sha256sums=(SKIP
+            4b723cf33b30f6176f8f50623c2325d05d5dc70463ca2bcd893fae2ccab5776e)
+
+build() {
+  cd pacman-hacks
+  make PREFIX=/usr
+}
+
+package() {
+  depends+=(bash curl expac grep gzip fakeroot libarchive pacman sed sh vi)
+
+  cd pacman-hacks
+  make \
+    DESTDIR="$pkgdir" \
+    SCRIPTS='diffrepo getpkg pkgmirror remakepkg repkg' \
+    MANPAGES='diffrepo getpkg pkgmirror remakepkg repkg' \
+    install
+  install -Dm 0644 README "$pkgdir"/usr/share/doc/remakepkg/README
+  install -Dm 0644 CHANGELOG "$pkgdir"/usr/share/doc/remakepkg/CHANGELOG
+  install -Dm 0644 "$srcdir"/diffrepo.hook.example \
+                   "$pkgdir"/usr/share/doc/remakepkg/diffrepo.hook.example
+}