Fork from Official Community/skaffold 1.20.0-1

1 files changed, 64 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..f51e0dac8eb8
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,64 @@
+# Maintainer Christian Rebischke <chris.rebischke@archlinux.org>
+# Maintainer: Fredy García <frealgagu at gmail dot com>
+# Maintainer: Maxim Baz <${pkgname} at maximbaz dot com>
+# Contributor: Stefan Cocora <stefan dot cocora at gmail dot com>
+
+pkgname=skaffold
+pkgver=1.20.0
+pkgrel=1
+pkgdesc="A command line tool that facilitates continuous development for Kubernetes applications"
+arch=("x86_64")
+url="https://github.com/GoogleContainerTools/${pkgname}"
+license=("Apache")
+depends=("docker")
+makedepends=("go")
+optdepends=(
+  "minikube: To use Minikube"
+  "kubectl: For Kubernetes support"
+  "bash-completion: Tab autocompletion"
+)
+source=(
+  "${pkgname}-${pkgver}.tar.gz::https://github.com/GoogleContainerTools/${pkgname}/archive/v${pkgver}.tar.gz"
+  "build_info.patch"
+)
+sha256sums=('d47ee974acf1c4432dab3ecdffeadbe271d2ff8098b811da2e73a04f9d9af957'
+            'e90797011d2f79c79a6b184a5e9c35c4e5c582622d075b0022675b96fccefc46')
+_commit="c48e97690d8daffd68141c2a68fcbe3df6f6936a"
+
+prepare() {
+  cd "${srcdir}/${pkgname}-${pkgver}"
+  patch -Np1 -i "${srcdir}/build_info.patch"
+
+  rm -rf "${srcdir}/gopath"
+  mkdir -p "${srcdir}/gopath/bin"
+  mkdir -p "${srcdir}/gopath/src/github.com/GoogleContainerTools"
+  ln -rTsf "${srcdir}/${pkgname}-${pkgver}" "${srcdir}/gopath/src/github.com/GoogleContainerTools/${pkgname}"
+}
+
+build() {
+  cd "${srcdir}/gopath/src/github.com/GoogleContainerTools/${pkgname}"
+  export GOPATH="${srcdir}/gopath"
+  export PATH="${PATH}:${GOPATH}/bin"
+  export VERSION="v${pkgver}"
+  export COMMIT="${_commit}"
+  export TREE_STATE="clean"
+  export CGO_CPPFLAGS="${CPPFLAGS}"
+  export CGO_CFLAGS="${CFLAGS}"
+  export CGO_CXXFLAGS="${CXXFLAGS}"
+  export CGO_LDFLAGS="${LDFLAGS}"
+  export GOFLAGS="-buildmode=pie -mod=readonly -modcacherw -x -v -ldflags=-linkmode=external"
+  make install
+
+  # To avoid issues deleting directories next time
+  go clean --modcache
+
+  # Create completion files
+  "${srcdir}/gopath/bin/${pkgname}" completion bash > "${srcdir}/${pkgname}-completion.bash"
+  "${srcdir}/gopath/bin/${pkgname}" completion zsh > "${srcdir}/${pkgname}-completion.zsh"
+}
+
+package() {
+  install -Dm755 "${srcdir}/gopath/bin/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
+  install -Dm644 "${srcdir}/${pkgname}-completion.bash" "${pkgdir}/usr/share/bash-completion/completions/${pkgname}"
+  install -Dm644 "${srcdir}/${pkgname}-completion.zsh" "${pkgdir}/usr/share/zsh/site-functions/_skaffold"
+}