initial commit

1 files changed, 47 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..0386f816d028
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,47 @@
+# Maintainer: Kian Kasad <kian at kasad.com>
+
+pkgname=sponsorblock-chromium-git
+pkgver=2.0.7.r38.4dc4160
+pkgrel=1
+pkgdesc="SponsorBlock extension for chromium-based browsers"
+arch=(any)
+url="https://github.com/ajayyy/SponsorBlock"
+license=('GPL')
+makedepends=('git' 'npm')
+provides=("${pkgname%-git}")
+conflicts=("${pkgname%-git}")
+source=("${pkgname%-git}::git+${url}.git")
+sha256sums=('SKIP')
+
+pkgver() {
+	cd "$srcdir/${pkgname%-git}"
+
+	# print version string
+	printf "%s" "$(git describe --long --tags | sed 's/\([^-]*-\)g/r\1/;s/-/./g')"
+}
+
+prepare() {
+	cd "$srcdir/${pkgname%-git}"
+
+	cp config.json.example config.json
+
+	# install build-time dependencies using npm
+	npm install
+}
+
+build() {
+	cd "$srcdir/${pkgname%-git}"
+
+	# build extension
+	npm run build
+}
+
+package() {
+	cd "$srcdir/${pkgname%-git}"
+
+	# create install dir
+	mkdir -p "$pkgdir/usr/share/"
+
+	# install extension files
+	cp -aT dist "$pkgdir/usr/share/${pkgname%-git}"
+}