summarylogtreecommitdiffstats
path: root/PKGBUILD
diff options
context:
space:
mode:
authorGaetan Bisson2015-06-08 11:31:00 -1000
committerGaetan Bisson2015-06-08 11:31:00 -1000
commitd24ea821b52ab30087241873c32001f64cbbd76d (patch)
tree83622172c9f84b56db0325a12c048fb1e6c944a8 /PKGBUILD
downloadaur-d24ea821b52ab30087241873c32001f64cbbd76d.tar.gz
initial commit
Diffstat (limited to 'PKGBUILD')
-rw-r--r--PKGBUILD49
1 files changed, 49 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..ff5e10ca18e6
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,49 @@
+# Maintainer: Gaetan Bisson <bisson@archlinux.org>
+# Contributor: Scytrin dai Kinthra <scytrin@gmail.com>
+
+pkgname=st-git
+_pkgname=st
+pkgver=20150603.71fa10f
+pkgrel=1
+pkgdesc='Simple virtual terminal emulator for X'
+url='http://git.suckless.org/st/'
+arch=('i686' 'x86_64' 'armv7h')
+license=('MIT')
+depends=('libxft')
+makedepends=('ncurses' 'libxext' 'git')
+source=('git://git.suckless.org/st'
+ 'scrollback.patch')
+sha1sums=('SKIP'
+ '2e10ac47eb020d50c7f861f3923bb4152255a027')
+
+provides=("${_pkgname}")
+conflicts=("${_pkgname}")
+
+pkgver() {
+ cd "${srcdir}/${_pkgname}"
+ git log -1 --format='%cd.%h' --date=short | tr -d -
+}
+
+prepare() {
+ cd "${srcdir}/${_pkgname}"
+ patch -p1 -i ../scrollback.patch # http://st.suckless.org/patches/st-scrollback.diff
+ sed \
+ -e '/char font/s/= .*/= "Fixed:pixelsize=13:style=SemiCondensed";/' \
+ -e '/char worddelimiters/s/= .*/= " '"'"'`\\\"()[]{}<>|";/' \
+ -e '/int defaultcs/s/= .*/= 1;/' \
+ -i config.def.h
+}
+
+build() {
+ cd "${srcdir}/${_pkgname}"
+ make X11INC=/usr/include/X11 X11LIB=/usr/lib/X11
+}
+
+package() {
+ cd "${srcdir}/${_pkgname}"
+ export TERMINFO="${pkgdir}/usr/share/terminfo"
+ install -d "$TERMINFO"
+ make PREFIX=/usr DESTDIR="${pkgdir}" install
+ install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+ install -Dm644 README "${pkgdir}/usr/share/doc/${pkgname}/README"
+}