Initial import

1 files changed, 39 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..06766bba0b61
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,39 @@
+# Maintainer: Martin Blumenstingl <martin.blumenstingl@googlemail.com>
+# Author: Antonio Rojas <arojas@archlinux.org>
+
+pkgname=telepathy-kde-filetransfer-handler-git
+pkgver=r184.482151e
+pkgrel=1
+pkgdesc='KDE Telepathy file transfer handler'
+arch=('i686' 'x86_64')
+url='http://community.kde.org/Real-Time_Communication_and_Collaboration'
+license=('GPL')
+depends=('telepathy-kde-common-internals-git')
+makedepends=('extra-cmake-modules' 'git' 'kdoctools' 'python')
+conflicts=('telepathy-kde-filetransfer-handler')
+source=("git://anongit.kde.org/ktp-filetransfer-handler.git")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd ktp-filetransfer-handler
+  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+prepare() {
+  mkdir -p build
+}
+
+build() {
+  cd build
+  cmake ../ktp-filetransfer-handler \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DLIB_INSTALL_DIR=lib \
+    -DKDE_INSTALL_USE_QT_SYS_PATHS=ON
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="${pkgdir}" install
+}