Initial commit

1 files changed, 41 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..3fb8150092c7
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,41 @@
+# Maintainer: Pando85 <pando855@gmail.com>
+
+# https://github.com/orhun/pkgbuilds
+
+pkgname=timer-rs
+pkgver=0.1.2
+pkgrel=1
+pkgdesc="Simple countdown terminal alarm"
+arch=('i686' 'x86_64' 'armv6h' 'armv7h' 'aarch64')
+url="https://github.com/pando85/timer"
+license=('GPL')
+depends=('gcc-libs'
+         'alsa-lib')
+makedepends=('cargo'
+             'git')
+source=("git+$url.git#tag=v${pkgver}?signed")
+validpgpkeys=('C15CDDF9318F14398300B917C6CB8A1793CA3F94')
+sha512sums=('SKIP')
+
+prepare() {
+    cd "$srcdir/timer"
+    cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
+}
+
+build() {
+    cd "$srcdir/timer"
+    export RUSTUP_TOOLCHAIN=stable
+    export CARGO_TARGET_DIR=target
+    cargo build --frozen --release --all-features
+}
+
+check() {
+    cd "$srcdir/timer"
+    export RUSTUP_TOOLCHAIN=stable
+    cargo test --frozen --all-features
+}
+
+package() {
+    cd "$srcdir/timer"
+    install -Dm0755 -t "$pkgdir/usr/bin/" "target/release/timer"
+}