newpkg: tpm2-tss-git

1 files changed, 39 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..2530c9d4de98
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,39 @@
+# Maintainer: Hexchain Tong <i at hexchain dot org>
+
+pkgname=tpm2-tss-git
+pkgver=r657.64b11df
+_pkgname=TPM2.0-TSS
+pkgrel=1
+pkgdesc="TPM (Trusted Platform Module) 2.0 Software Stack (TSS)"
+arch=('i686' 'x86_64')
+provides=('tpm2-tss')
+conflicts=('tpm2-tss')
+url="https://github.com/01org/TPM2.0-TSS"
+license=('custom')
+makedepends=('git' 'cmocka' 'autoconf-archive')
+depends=('gcc-libs')
+source=('git+https://github.com/01org/TPM2.0-TSS.git')
+md5sums=('SKIP')
+
+pkgver() {
+    cd "$srcdir/$_pkgname"
+    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+build() {
+    cd "$srcdir/$_pkgname"
+    ./bootstrap
+    ./configure --prefix=/usr --sbindir=/usr/bin --disable-static
+    make
+}
+
+check() {
+    cd "$srcdir/$_pkgname"
+    make -k check
+}
+
+package() {
+    cd "$srcdir/$_pkgname"
+    make DESTDIR="$pkgdir/" install
+    install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}