packaging update

1 files changed, 23 insertions, 10 deletions

diff --git a/PKGBUILD b/PKGBUILD
index b090b6e064c2..f08feb86a5e5 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,19 +1,32 @@
-# Maintainer: GI_Jack <GI_Jack@hackermail.com>
+# Maintainer: Luis Martinez <luis dot martinez at disroot dot org>
+# Contributor: GI_Jack <GI_Jack@hackermail.com>
+
 pkgname=trackerjacker
 pkgver=1.9.0
-pkgrel=1
-pkgdesc="Map and track WiFi networks and devices through raw 802.11 monitoring."
+pkgrel=2
+pkgdesc="Map and track WiFi networks and devices through raw 802.11 monitoring"
 arch=('any')
 url="https://github.com/calebmadrigal/trackerjacker"
 license=('MIT')
-depends=('python' 'python-setuptools' 'python-scapy' 'python-pyaml' 'python-ruamel-yaml')
-source=("https://files.pythonhosted.org/packages/95/d7/74790c2071d9dfeb8cc3b3cf401350b880c0533d5eac584ef10c35bfc640/trackerjacker-${pkgver}.tar.gz")
+depends=('python-pyaml' 'python-ruamel-yaml' 'python-scapy')
+makedepends=('python-build' 'python-installer' 'python-setuptools' 'python-wheel')
+source=("$pkgname-$pkgver.tar.gz::https://files.pythonhosted.org/packages/source/t/$pkgname/$pkgname-$pkgver.tar.gz")
 sha256sums=('d11c984c85eb5c9ffec5d5ae74eaaa1bed273b827c9cb28511b3bab22d71f3fd')
 
+prepare() {
+	cd "$pkgname-$pkgver"
+	sed -i 's/[=<>]=.*//g' requirements.txt
+}
+
+build() {
+	cd "$pkgname-$pkgver"
+	python -m build --wheel --no-isolation
+}
+
 package() {
-  cd "${pkgname}-$pkgver"
-  sed -i s/'ruamel.yaml==0.15.0'/'ruamel.yaml'/g requirements.txt
-  sed -i s/'scapy==2.4.0'/'scapy'/g requirements.txt
-  sed -i s/'pyaml>=17.12.1'/'pyaml'/g requirements.txt
-  python setup.py install -O1 --root="${pkgdir}" --prefix=/usr
+	cd "$pkgname-$pkgver"
+	python -m installer --destdir "$pkgdir" dist/*.whl
+	local _site="$(python -c 'import site; print(site.getsitepackages()[0])')"
+	install -dv "$pkgdir/usr/share/licenses/$pkgname/"
+	ln -sv "$_site/$pkgname-$pkgver.dist-info/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/"
 }