Initial commit

1 files changed, 43 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..0040073d3aeb
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,43 @@
+# Maintainer: Trizen <echo dHJpemVuQHByb3Rvbm1haWwuY29tCg== | base64 -d>
+
+_pkgname=trizen
+pkgname=trizen-git
+pkgver=1.25.1.g8463e3f
+pkgrel=1
+pkgdesc="Trizen's AUR Package Manager: A lightweight wrapper for AUR (-git version)."
+arch=('any')
+url="https://github.com/trizen/${_pkgname}"
+license=('GPL3')
+
+provides=('trizen')
+conflicts=('trizen')
+
+depends=(
+         'git'
+         'diffutils'
+         'perl>=5.14.0'
+         'perl-libwww'
+         'perl-term-ui'
+         'pacman'
+         'perl-json'
+         'perl-data-dump'
+         'perl-lwp-protocol-https'
+        )
+
+optdepends=(
+            'perl-json-xs: faster JSON deserialization'
+            'perl-term-readline-gnu: for better STDIN support'
+           )
+
+source=("git://github.com/trizen/${_pkgname}.git")
+sha256sums=('SKIP')
+
+pkgver() {
+    cd "$_pkgname"
+    git describe --always | sed -e 's|-|.|g'
+}
+
+package() {
+  cd "$_pkgname"
+  install -m 755 -D "$_pkgname" "$pkgdir/usr/bin/${_pkgname}"
+}