Initial import

1 files changed, 39 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..5a4331fac867
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,39 @@
+# Maintainer: Igor Dyatlov <dyatlov.igor@protonmail.com>
+
+pkgname=twitch-dl-git
+pkgver=1.16.1.r5.gdd1f4e0
+pkgrel=1
+pkgdesc="Twitch video downloader that use multiple concurrent connections"
+arch=(any)
+url="https://github.com/ihabunek/twitch-dl"
+license=('GPL3')
+depends=('python' 'python-m3u8' 'ffmpeg')
+makedepends=('python-setuptools')
+checkdepends=('python-pytest')
+provides=('twitch-dl' 'twitch-dl-bin')
+conflicts=('twitch-dl' 'twitch-dl-bin')
+source=(git+$url.git)
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "${pkgname%-git}"
+  ( set -o pipefail
+    git describe --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
+    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+  )
+}
+
+build() {
+  cd "${pkgname%-git}"
+  make 
+}
+
+check(){
+  cd "${pkgname%-git}"
+  python setup.py pytest
+}
+
+package() {
+  cd "${pkgname%-git}"
+  python setup.py install --root="$pkgdir" --optimize=1
+}