Initial commit

1 files changed, 42 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..0bfad46535ef
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,42 @@
+# Maintainer:  Gustavo Alvarez <sl1pkn07@gmail.com>
+
+_plug=cmedian
+pkgname=vapoursynth-plugin-${_plug}-git
+pkgver=v1.0.gc19dd5c
+pkgrel=1
+pkgdesc="Plugin for Vapoursynth: ${_plug} (GIT version)"
+arch=('x86_64')
+url='https://bitbucket.org/James1201/vapoursynth-cmedian'
+license=('LGPL2.1')
+depends=('vapoursynth')
+makedepends=('git'
+             'meson'
+             )
+provides=("vapoursynth-plugin-${_plug}")
+conflicts=("vapoursynth-plugin-${_plug}-hg"
+           "vapoursynth-plugin-${_plug}")
+source=("${_plug}::git+https://github.com/4re/vapoursynth-cmedian.git")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "${_plug}"
+  echo "$(git describe --long --tags | tr - .)"
+}
+
+prepare() {
+  mkdir -p build
+}
+
+build() {
+  cd build
+  arch-meson "../${_plug}" \
+    --libdir /usr/lib/vapoursynth
+
+  ninja
+}
+
+package(){
+  DESTDIR="${pkgdir}" ninja -C build install
+
+  install -Dm644 "${_plug}/README.md" "${pkgdir}/usr/share/doc/vapoursynth/plugins/${_plug}/README.md"
+}