Migration

1 files changed, 72 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..107e23e3fb52
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,72 @@
+# Maintainer: Alfredo Ramos <alfredo dot ramos at yandex dot com>
+# Contributor: Arthur Țițeică arthur.titeica/gmail/com
+# Contributor: Thomas Laube <tomx3@tomtomtom.org>
+
+_pkgname=vokoscreen
+pkgname=${_pkgname}-git
+pkgver=2.3.4.beta.r3.gd712c7b
+pkgrel=1
+pkgdesc='An easy to use screencast creator. Qt5 build. Development version.'
+arch=('i686' 'x86_64')
+url='http://linuxecke.volkoh.de/vokoscreen/vokoscreen.html'
+license=('GPL')
+
+depends=('ffmpeg' 'lame' 'qt5-x11extras')
+optdepends=(
+	'pulseaudio-alsa: For PulseAudio support'
+)
+makedepends=('git' 'qt5-tools')
+provides=("${_pkgname}=${pkgver}")
+conflicts=("${_pkgname}")
+
+source=(
+	"git+https://github.com/vkohaupt/${_pkgname}.git"
+	'desktop_file.patch'
+)
+sha512sums=(
+	'SKIP'
+	'3ddc567f831b9f6e2672997a77a099cf8fdd5a6a1d79157738c1670c9106fd6c4e09d74287a770c19bac23dcb73a19ce69cc1ac893d4988f75c7ac35668f7a90'
+)
+
+pkgver() {
+	# Updating package version
+	cd ${srcdir}/${_pkgname}
+	(
+		set -o pipefail
+		git describe --long --tags 2>/dev/null | sed -r 's/([^-]*-g)/r\1/;s/-/./g' ||
+		printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+	)
+}
+
+prepare() {
+	# Patching *.desktop file
+	cd ${srcdir}/${_pkgname}
+	patch ./applications/${_pkgname}.desktop ../desktop_file.patch
+
+	# Create build directory
+	mkdir -p ${srcdir}/build
+}
+
+build() {
+	# Number of jobs
+	declare -i njobs=$(nproc)
+
+	if [[ ${njobs} -ge 8 ]]; then
+		njobs=$(( $njobs - 2 ))
+	fi
+
+	# Building package
+	cd ${srcdir}/build
+	qmake-qt5 ../${_pkgname} \
+		CONFIG+=release \
+		CONFIG+=c++14 \
+		-spec linux-g++
+
+	make -j${njobs}
+}
+
+package() {
+	# Installing package
+	cd ${srcdir}/build
+	make INSTALL_ROOT=${pkgdir} install
+}
\ No newline at end of file