Initial import to AUR4 (v1.8.1)

1 files changed, 41 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..96a6236e1ce4
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,41 @@
+# Maintainer:  Eric Biggers <ebiggers3 at gmail dot com>
+
+pkgname=wimlib
+pkgver=1.8.1
+pkgrel=1
+pkgdesc="A library and program to extract, create, and modify WIM files"
+arch=("i686" "x86_64")
+url="http://sourceforge.net/projects/wimlib"
+license=("custom")
+depends=("openssl" "fuse" "libxml2" "ntfs-3g" "attr")
+optdepends=("cdrkit: for making ISO image of Windows PE"
+	"mtools: for making disk image of Windows PE"
+	"syslinux: for making disk image of Windows PE"
+	"cabextract: for extracting Windows PE from the WAIK"
+	"ntfsprogs: for making NTFS filesystems")
+checkdepends=("ntfsprogs")
+source=("http://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver.tar.gz")
+
+build() {
+	cd "$pkgname-$pkgver"
+	./configure --with-libcrypto --with-fuse --with-ntfs-3g --prefix=/usr
+	make
+}
+
+check() {
+	cd "$pkgname-$pkgver"
+	make check
+}
+
+package() {
+	cd "$pkgname-$pkgver"
+	make DESTDIR="$pkgdir" install
+	for file in NEWS README*; do
+		install -Dm644 $file "$pkgdir/usr/share/doc/$pkgname/$file"
+	done
+	for file in COPYING*; do
+		install -Dm644 $file "$pkgdir/usr/share/licenses/$pkgname/$file"
+	done
+}
+
+sha1sums=('919eec5f226932b492cb54c00a9a2aacbf480b82')