Rebase

Signed-by: PedroHLC <root@pedrohlc.com>

1 files changed, 88 insertions, 37 deletions

diff --git a/PKGBUILD b/PKGBUILD
index ac62e2b43bb9..8f680dc7011f 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,57 +1,108 @@
-# Contributor: bin <bin at datacowboy dot cf>
-# Contributor: Eric Engestrom <aur [at] engestrom [dot] ch>
+# Maintainer: Ferdinand Bachmann <ferdinand.bachmann@yrlf.at>
 # Contributor: David Runge <dvzrv@archlinux.org>
-# Contributor: Pedro Lara Campos <root@pedrohlc.com>
-# Contributor: Eduard Tolosa <edu4rdshl@protonmail.com>
+# Contributor: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
 
-_pkgname=wireplumber
-pkgname="${_pkgname}-git"
-pkgver=0.4.8.r33.gf46a801
+_pkgbase=wireplumber
+pkgbase=wireplumber-git
+pkgname=(
+  wireplumber-git
+  libwireplumber-git
+)
+pkgver=0.4.81.r22.g6f3eb329
 pkgrel=1
 pkgdesc="Session / policy manager implementation for PipeWire"
-arch=('x86_64')
-url="https://gitlab.freedesktop.org/pipewire/wireplumber"
-license=('MIT')
-depends=('gcc-libs' 'glibc' 'lua' 'libgio-2.0.so' 'libglib-2.0.so'
-  'libgmodule-2.0.so' 'libgobject-2.0.so' 'libpipewire-0.3.so')
-makedepends=('cmake' 'cpptoml' 'glib2' 'gobject-introspection' 'meson' 'pipewire'
-  'doxygen' 'glib2'  'python-breathe' 'python-lxml' 'python-sphinx_rtd_theme'
-  'python-sphinx' 'systemd' 'git')
-checkdepends=('pipewire-alsa' 'pipewire-jack' 'pipewire-pulse')
-install='wireplumber.install'
-provides=("wireplumber=${pkgver}" 'libwireplumber-0.4.so' 'pipewire-session-manager')
-conflicts=('wireplumber' 'pipewire-media-session')
-source=("git+$url.git")
-sha512sums=('SKIP')
+url="https://pipewire.pages.freedesktop.org/wireplumber/"
+arch=(x86_64)
+license=(MIT)
+makedepends=(
+  doxygen
+  git
+  glib2
+  gobject-introspection
+  graphviz
+  lua
+  meson
+  pipewire
+  python-lxml
+  systemd
+)
+checkdepends=(pipewire-audio)
+source=("git+https://gitlab.freedesktop.org/pipewire/$_pkgbase.git")
+b2sums=('SKIP')
 
 pkgver() {
-  cd "$_pkgname"
+  cd $_pkgbase
+  git describe --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+}
 
-  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+prepare() {
+  cd $_pkgbase
 }
 
 build() {
-  cd "$_pkgname"
-
-  arch-meson \
-    -Dsystem-lua=true \
-    -Delogind=disabled \
-    build
+  local meson_options=(
+    -D doc=disabled
+    -D elogind=disabled
+    -D system-lua=true
+  )
 
-  ninja -C build
+  arch-meson $_pkgbase build "${meson_options[@]}"
+  meson compile -C build
 }
 
 check() {
-  cd "$_pkgname"
+  meson test -C build --print-errorlogs
+}
 
-  ninja -C build test || echo "Known to fail: https://gitlab.freedesktop.org/pipewire/wireplumber/-/issues/18"
+_pick() {
+  local p="$1" f d; shift
+  for f; do
+    d="$srcdir/$p/${f#$pkgdir/}"
+    mkdir -p "$(dirname "$d")"
+    mv "$f" "$d"
+    rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
+  done
 }
 
-package() {
-  cd "$_pkgname"
+_ver=0.5
+
+package_wireplumber-git() {
+  depends=(
+    "libwireplumber-git=$pkgver-$pkgrel"
+    libsystemd.so
+    lua
+    pipewire
+  )
+  provides=(pipewire-session-manager "wireplumber=$pkgver")
+  conflicts=(pipewire-media-session wireplumber)
+  install=wireplumber.install
+
+  meson install -C build --destdir "$pkgdir"
 
-  DESTDIR="${pkgdir}" meson install -C build
-  install -vDm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
-  install -vDm 644 {NEWS,README}.rst -t "${pkgdir}/usr/share/doc/${pkgname}"
+  (
+    cd "$pkgdir"
+
+    _pick libw usr/lib/libwireplumber-$_ver.so*
+    _pick libw usr/lib/girepository-1.0
+    _pick libw usr/lib/pkgconfig
+    _pick libw usr/include
+    _pick libw usr/share/gir-1.0
+  )
+
+  install -Dt "$pkgdir/usr/share/doc/$pkgname" -m644 $_pkgbase/{NEWS,README}*
+  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 $_pkgbase/LICENSE
 }
 
+package_libwireplumber-git() {
+  pkgdesc+=" - client library"
+  depends=(
+    libg{lib,module,object,io}-2.0.so
+    libpipewire-0.3.so
+  )
+  provides=(libwireplumber-$_ver.so "libwireplumber=$pkgver")
+  conflicts=(libwireplumber)
+
+  mv libw/* "$pkgdir"
+
+  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 $_pkgbase/LICENSE
+}