Initial commit

1 files changed, 58 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..0c4ec52fc99a
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,58 @@
+# Maintainer: tarball <bootctl@gmail.com>
+
+pkgname='wiretrustee-bin'
+_pkgname="${pkgname%-bin}"
+pkgver=0.0.7
+pkgrel=1
+pkgdesc='Connect your devices into a single secure private WireGuard®-based mesh network'
+url='https://wiretrustee.com'
+arch=(x86_64 aarch64)
+license=('BSD')
+
+provides=("${_pkgname}")
+conflicts=("${_pkgname}")
+depends=()
+makedepends=()
+optdepends=()
+
+source=(
+  'config_readme'
+  'environment'
+  'wiretrustee@.service'
+  'wiretrustee-signal.service'
+)
+sha256sums=(
+  'e6e2bb1687510b9381202d95beb27b1bfbe30033f4f038e4bdde61e7a3f65f22'
+  'c72c3f27ee2f2fbb232108781e38f41d7f04272d11a42f59938541ac591bd393'
+  '672235231a73743878d77e94827c5aba326464dae63457f94cd51708ac84ba58'
+  '79cae90dff3bb3177762b9d3a9c69e69ef79ced3dc3a85529ff5050bf17bcd85'
+)
+
+_base_url="https://github.com/${_pkgname}/${_pkgname}/releases/download/v${pkgver}/${_pkgname}_${pkgver}_linux"
+
+source_x86_64=("${pkgname}-${pkgver}.tar.gz::${_base_url}_amd64.tar.gz")
+sha256sums_x86_64=('5d11b291346badadfc8589d04877b6912a7133e28d3c7bdfd2795cec706a9bfe')
+
+source_aarch64=("${pkgname}-${pkgver}.tar.gz::${_base_url}_arm64.tar.gz")
+sha256sums_aarch64=('ce02dbfee5e0fbe4e586d4f2a1384c661774c19b0bcbc29b180b83f40567d9a6')
+
+package() {
+  # binary
+  install -Dm755 "${_pkgname}" "${pkgdir}/usr/bin/${_pkgname}"
+
+  # config directory
+  install -Ddm755 -o root -g root "${pkgdir}/etc/${_pkgname}"
+  install -Dm644 "config_readme" "${pkgdir}/etc/${_pkgname}/README"
+
+  # environment file
+  install -Dm644 environment "${pkgdir}/etc/default/${_pkgname}"
+
+  # systemd units
+  for kind in @ -signal; do
+    install -Dm644 "${_pkgname}${kind}.service" \
+      "${pkgdir}/usr/lib/systemd/system/${_pkgname}${kind}.service"
+  done
+
+  # license
+  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}