Initial import 11.1.0.9080

1 files changed, 85 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..65404c2b343f
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,85 @@
+# Maintainer: Astro Benzene <universebenzene at sina dot com>
+# Contributor: Felix Yan <felixonmars@archlinux.org>
+# Contributor: Ouyang Jun <ouyangjun1999@gmail.com>
+# Contributor: Jove Yu <yushijun110 [at] gmail.com>
+# Contributor: Ariel AxionL <axionl at aosc dot io>
+
+pkgbase=wps-office-cn
+pkgname=('wps-office-cn' 'wps-office-mime-cn')
+pkgver=11.1.0.9080
+pkgrel=1
+pkgdesc="Kingsoft Office (WPS Office) cn version - an office productivity suite"
+arch=('x86_64')
+license=('custom')
+url="https://linux.wps.cn"
+options=('!emptydirs')
+source=("https://wdl1.cache.wps.cn/wps/download/ep/Linux2019/${pkgver##*.}/wps-office_${pkgver}_amd64.deb")
+sha1sums=('7daa9c0fdbf244daf92f057e93e71bd6cf46005d')
+
+prepare() {
+    bsdtar -xpf data.tar.xz
+
+    cd "${srcdir}/usr/bin"
+    sed -i 's|/opt/kingsoft/wps-office|/usr/lib|' *
+
+    cd "${srcdir}/usr/share/icons/hicolor"
+    for _file in ./*; do
+        if [ -e ${_file}/mimetypes/wps-office2019-etmain.png ]; then
+            mkdir -p ${_file}/apps
+            cp -p ${_file}/mimetypes/wps-office2019* ${_file}/apps
+        fi
+    done
+}
+
+package_wps-office-cn() {
+    depends=('fontconfig' 'xorg-mkfontdir' 'libxrender' 'gtk2' 'desktop-file-utils' 'shared-mime-info' 'xdg-utils' 'glu' 'openssl-1.0' 'sdl2' 'libpulse' 'hicolor-icon-theme' 'libxss' 'sqlite' 'libtool')
+    optdepends=('cups: for printing support'
+                'libjpeg-turbo: JPEG image codec support'
+                'pango: for complex (right-to-left) text support'
+                'curl: An URL retrieval utility and library'
+                'ttf-wps-fonts: Symbol fonts required by wps-office'
+                'ttf-ms-fonts: Microsft Fonts recommended for wps-office'
+                'wps-office-fonts: FZ TTF fonts provided by wps community'
+                'wps-office-mime-cn: Use mime files provided by Kingsoft')
+    install=${pkgname}.install
+    conflicts=('kingsoft-office' 'wps-office')
+    provides=('wps-office')
+    cd "${srcdir}/opt/kingsoft/wps-office/"
+
+    install -d "${pkgdir}/usr/lib"
+    cp -r office6 "${pkgdir}/usr/lib"
+    install -Dm644 -t "${pkgdir}/usr/share/licenses/${pkgname}" office6/mui/default/*.txt
+
+    install -d "${pkgdir}/usr/bin"
+    cd "${srcdir}/usr/bin"
+    install -m755 * "${pkgdir}/usr/bin"
+
+    cd "${srcdir}/usr/share"
+
+    install -d "${pkgdir}/usr/share/applications"
+    cp -r applications/* "${pkgdir}/usr/share/applications"
+
+    install -d "${pkgdir}/usr/share/desktop-directories"
+    cp -r desktop-directories/* "${pkgdir}/usr/share/desktop-directories"
+
+    install -d "${pkgdir}/usr/share/icons"
+    cp -r icons/* "${pkgdir}/usr/share/icons"
+
+    install -Dm644 -t "${pkgdir}/usr/share/fonts/wps-office" fonts/wps-office/*
+
+    install -Dm644 -t "${pkgdir}/etc/xdg/menus/applications-merged" "${srcdir}/etc/xdg/menus/applications-merged/wps-office.menu"
+}
+
+package_wps-office-mime-cn() {
+    pkgdesc="Mime files provided by Kingsoft Office (WPS Office) cn version"
+    depends=('shared-mime-info')
+    conflicts=('wps-office-mime')
+    provides=('wps-office-mime')
+    cd "${srcdir}/usr/share"
+
+    install -d "${pkgdir}/usr/share/mime"
+    cp -r mime/* "${pkgdir}/usr/share/mime"
+
+    cd "${srcdir}/opt/kingsoft/wps-office/"
+    install -Dm644 -t "${pkgdir}/usr/share/licenses/${pkgname}" office6/mui/default/*.txt
+}