initial version

1 files changed, 49 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..77ae50413c01
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,49 @@
+# Maintainer: Brian Bidulock <bidulock@openss7.org>
+# Contributor: Alexander Baldeck <alexander@archlinux.org>
+# Contributor: Jan de Groot <jgc@archlinux.org>
+pkgname=xorg-xdm-xlogin-git
+pkgver=1.1.11.71.gb80fc37
+pkgrel=1
+pkgdesc="X Display Manager"
+arch=(i686 x86_64)
+#url="http://xorg.freedesktop.org/"
+url="https://github.com/bbidulock/xdm"
+license=('custom')
+depends=('libbsd' 'pam' 'libxaw' 'libxinerama' 'xorg-xrdb' 'xorg-sessreg' 'libxft' 'systemd')
+optdepends=('slim-xdm: for separate greeter')
+provides=('xorg-xdm' 'xorg-xdm-xlogin')
+conflicts=('xorg-xdm' 'xorg-xdm-xlogin' 'xorg-xdm-git')
+makedepends=('git' 'pkgconfig' 'xorg-util-macros' 'xtrans')
+backup=(etc/X11/xdm/Xaccess etc/X11/xdm/Xresources etc/X11/xdm/Xservers etc/X11/xdm/xdm-config etc/pam.d/xdm etc/pam.d/greeter etc/X11/xdm/Xsetup_0 etc/X11/xdm/Xsession)
+source=("$pkgname::git+https://github.com/bbidulock/xdm.git")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe | sed 's,xdm-,,;s,-,.,g'
+}
+
+build() {
+  cd $pkgname
+  ./autogen.sh --prefix=/usr \
+      --sysconfdir=/etc \
+      --disable-xdm-auth \
+      --disable-static \
+      --with-xdmconfigdir=/etc/X11/xdm \
+      --with-xdmscriptdir=/etc/X11/xdm \
+      --with-pixmapdir=/usr/share/xdm/pixmaps
+  make CWARNFLAGS=""
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="${pkgdir}" install
+  install -m755 -d "${pkgdir}/var/lib/xdm"
+  install -m755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
+  install -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/"
+
+  sed -i -e 's/\/X11R6//g' "${pkgdir}"/etc/X11/xdm/*
+
+  sed -i 's|^Alias=.*|Alias=display-manager.service|' \
+    "$pkgdir/usr/lib/systemd/system/xdm.service"
+}