Add a PKGBUILD for yabridge-git

1 files changed, 45 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..d3541b42daed
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,45 @@
+# Maintainer: Robbert van der Helm <mail@robbertvanderhelm.nl>
+
+pkgname=yabridge-git
+_pkgname=yabridge
+pkgver=1.0.0.r23.g8049385
+pkgrel=1
+pkgdesc="Yet Another VST bridge, run Windows VST2 plugins under Linux"
+arch=('x86_64')
+url="https://github.com/robbert-vdh/yabridge"
+license=('GPL3')
+depends=('wine' 'libxcb' 'lib32-libxcb')
+makedepends=('meson' 'ninja' 'boost' 'lib32-boost-libs')
+provides=('yabridge')
+conflicts=('yabridge')
+install='yabridge.install'
+source=('git+https://github.com/robbert-vdh/yabridge')
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "$_pkgname"
+  git describe --long | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+  cd "$_pkgname"
+
+  # If you don't want to build lib32-boost-libs and you don't need the 32-bit
+  # bitbridge, then you can leave out the dependency for it and set the
+  # `use-bitbridge` option to false.
+  meson setup --buildtype=release --cross-file cross-wine.conf -Duse-bitbridge=true build
+  ninja -C build
+}
+
+package() {
+  cd "$_pkgname/build"
+
+  install -dm755 "${pkgdir}"/usr/bin
+  install yabridge-host.exe{,.so} "${pkgdir}"/usr/bin
+  install yabridge-host-32.exe{,.so} "${pkgdir}"/usr/bin
+
+  install -dm755 "${pkgdir}"/usr/lib
+  install libyabridge.so "${pkgdir}"/usr/lib
+}
+
+# vim:set ts=2 sw=2 et: