initial import of yubikey-personalization-git 1.17.1.r0.g717a772-1

1 files changed, 49 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..09c947e661ab
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,49 @@
+# Maintainer: Christian Hesse <mail@eworm.de>
+
+pkgname=yubikey-personalization-git
+pkgver=1.17.1.r0.g717a772
+pkgrel=1
+pkgdesc='Yubico YubiKey Personalization library and tool - git checkout'
+arch=('i686' 'x86_64')
+url='https://github.com/Yubico/yubikey-personalization'
+license=('BSD')
+depends=('libusb' 'yubico-c-client')
+makedepends=('git')
+provides=('ykpers' 'yubikey-personalization')
+conflicts=('ykpers' 'yubikey-personalization')
+install=yubikey-personalization.install
+source=('git://github.com/Yubico/yubikey-personalization.git')
+sha256sums=('SKIP')
+
+pkgver() {
+	cd yubikey-personalization/
+
+	if GITTAG="$(git describe --abbrev=0 --tags 2>/dev/null)"; then
+		echo "$(sed -e "s/^${pkgname%%-git}//" -e 's/^[-_/a-zA-Z]\+//' -e 's/[-_+]/./g' <<< ${GITTAG}).r$(git rev-list --count ${GITTAG}..).g$(git log -1 --format="%h")"
+	else
+		echo "0.r$(git rev-list --count master).g$(git log -1 --format="%h")"
+	fi
+}
+
+build() {
+	cd yubikey-personalization/
+
+	autoreconf -fi
+	./configure --prefix=/usr --with-udevrulesdir=/usr/lib/udev/rules.d/
+	make
+}
+
+check() {
+	cd yubikey-personalization/
+
+	make check
+}
+
+package() {
+	cd yubikey-personalization/
+
+	install -D -m0644 COPYING "${pkgdir}/usr/share/licenses/yubikey-personalization/COPYING"
+	install -D -m0644 README "${pkgdir}/usr/share/doc/yubikey-personalization/README"
+	make DESTDIR="${pkgdir}/" install
+}
+