Initial Commit

1 files changed, 77 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..42fd7da16f6a
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,77 @@
+# Maintainer: Zion Nimchuk <zionnimchuk@gmail.com>
+_pkgbase='yuzu'
+pkgbase="$_pkgbase-git"
+pkgname=("$_pkgbase-git" "$_pkgbase-qt-git")
+pkgver=5434.bf1084f
+pkgrel=1
+pkgdesc="An experimental open-source Nintendo Switch emulator/debugger"
+arch=('i686' 'x86_64')
+url="https://github.com/citra-emu/citra/"
+license=('GPL2')
+makedepends=('git' 'cmake' 'sdl2' 'qt5-base' 'shared-mime-info' 'desktop-file-utils')
+source=("$_pkgbase::git+https://github.com/yuzu-emu/yuzu"
+        'git+https://github.com/yuzu-emu/ext-boost'
+        'git+https://github.com/philsquared/Catch'
+        'git+https://github.com/MerryMage/dynarmic'
+        'git+https://github.com/herumi/xbyak'
+        'git+https://github.com/fmtlib/fmt')
+md5sums=('SKIP'
+         'SKIP'
+         'SKIP'
+         'SKIP'
+         'SKIP'
+         'SKIP')
+
+pkgver() {
+	cd "$srcdir/$_pkgbase"
+	echo "r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
+}
+
+prepare() {
+	cd "$srcdir/$_pkgbase"
+	mkdir -p build
+
+	git submodule init
+	git config submodule.boost.url "$srcdir/ext-boost"
+	git config submodule.catch.url "$srcdir/Catch"
+	git config submodule.dynarmic.url "$srcdir/dynarmic"
+	git config submodule.xbyak.url "$srcdir/xbyak"
+	git config submodule.fmt.url "$srcdir/fmt"
+	git config submodule.inih.url "$srcdir/inih"
+	git submodule update
+
+	cd externals/dynarmic
+	git config submodule.externals/fmt.url "$srcdir/fmt"
+	git config submodule.externals/xbyak.url "$srcdir/xbyak"
+	git submodule update
+}
+
+build() {
+	cd "$srcdir/$_pkgbase/build"
+	cmake .. \
+	  -DCMAKE_INSTALL_PREFIX=/usr \
+	  -DCMAKE_BUILD_TYPE=Release \
+	  -DUSE_SYSTEM_CURL=ON
+	make
+}
+
+check() {
+	cd "$srcdir/$_pkgbase/build"
+	make test
+}
+
+package_yuzu-git() {
+	depends=('sdl2' 'libpng')
+
+	install -Dm755 "$srcdir/$_pkgbase/build/src/yuzu/yuzu" "$pkgdir/usr/bin/$_pkgbase"
+}
+
+package_yuzu-qt-git() {
+	depends=('qt5-base' 'sdl2' 'shared-mime-info' 'desktop-file-utils')
+	optdepends=('libxkbcommon-x11: for X11 support'
+	            'qt5-wayland: for Wayland support')
+
+	cd "$srcdir/$_pkgbase/build"
+	make DESTDIR="$pkgdir/" install
+	rm "$pkgdir/usr/bin/$_pkgbase"
+}