summarylogtreecommitdiffstats
diff options
context:
space:
mode:
-rw-r--r--.SRCINFO20
-rwxr-xr-xPKGBUILD52
2 files changed, 72 insertions, 0 deletions
diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 00000000000..4d4f8e10c07
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,20 @@
+pkgbase = lib32-wayland-git
+ pkgdesc = A computer display server protocol
+ pkgver = 1.17.0.r18.g6908c8c
+ pkgrel = 1
+ url = https://wayland.freedesktop.org/
+ arch = x86_64
+ license = MIT
+ makedepends = git
+ depends = lib32-glibc
+ depends = lib32-libffi
+ depends = lib32-expat
+ depends = lib32-libxml2
+ depends = wayland
+ provides = lib32-wayland
+ conflicts = lib32-wayland
+ source = git+https://gitlab.freedesktop.org/wayland/wayland.git
+ sha256sums = SKIP
+
+pkgname = lib32-wayland-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100755
index 00000000000..3c7883b3a7e
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,52 @@
+# Maintainer: Vincent Grande <shoober420@gmail.com>
+# Contributor: Daniel Bermond < gmail-com: danielbermond >
+# Contributor: Joel Teichroeb <joel@teichroeb.net>
+# Contributor: Scimmia
+
+pkgbase=lib32-wayland-git
+pkgname=('lib32-wayland-git')
+pkgver=1.17.0.r18.g6908c8c
+pkgrel=1
+pkgdesc='A computer display server protocol'
+arch=('x86_64')
+url='https://wayland.freedesktop.org/'
+provides=('lib32-wayland')
+conflicts=('lib32-wayland')
+license=('MIT')
+depends=('lib32-glibc' 'lib32-libffi' 'lib32-expat' 'lib32-libxml2' 'wayland')
+makedepends=('git')
+source=('git+https://gitlab.freedesktop.org/wayland/wayland.git')
+sha256sums=('SKIP')
+
+pkgver() {
+ cd wayland
+
+ # git, tags available
+ git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/^v//'
+}
+
+build() {
+ cd wayland
+
+ export CC='gcc -m32'
+ export PKG_CONFIG_PATH=/usr/lib32/pkgconfig
+
+ ./autogen.sh \
+ --prefix='/usr' \
+ --libdir=/usr/lib32 \
+ --disable-documentation \
+ --disable-static
+
+ sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+
+ make
+}
+
+package() {
+
+ make DESTDIR="${pkgdir}" -C wayland install
+ rm -rf "${pkgdir}"/usr/{bin,include,share}
+
+ install -dm 755 "${pkgdir}"/usr/share/licenses
+ ln -s wayland "${pkgdir}"/usr/share/licenses/lib32-wayland
+}