1 files changed, 36 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..b9f13c1deb57
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,36 @@
+# Maintainer: Gonzalo Exequiel Pedone <hipersayan DOT x AT gmail DOT com>
+# Contributor: Antonio Rojas <arojas@archlinux.org>
+
+_android_arch=x86
+
+pkgname=android-${_android_arch}-imath
+pkgver=3.1.11
+pkgrel=1
+pkgdesc="A C++ and python library of 2D and 3D vector, matrix, and math operations for computer graphics (Android ${_android_arch})"
+arch=('any')
+url='https://www.openexr.com/'
+license=('BSD-3-Clause')
+depends=('android-ndk')
+makedepends=('android-cmake'
+             "android-${_android_arch}-boost")
+options=(!strip !buildflags staticlibs !emptydirs)
+source=("https://github.com/AcademySoftwareFoundation/Imath/archive/v$pkgver/imath-$pkgver.tar.gz")
+sha256sums=('9057849585e49b8b85abe7cc1e76e22963b01bfdc3b6d83eac90c499cd760063')
+
+build() {
+    cd "${srcdir}/Imath-$pkgver"
+    source android-env ${_android_arch}
+
+    android-${_android_arch}-cmake \
+        -S . \
+        -B build
+    cmake --build build
+}
+
+package() {
+    cd "${srcdir}/Imath-$pkgver"
+    source android-env ${_android_arch}
+
+    DESTDIR="$pkgdir" cmake --install build
+    ${ANDROID_STRIP} -g --strip-unneeded "${pkgdir}"/${ANDROID_PREFIX_LIB}/*.so
+}