1 files changed, 56 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..c3ea9c03a99a
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,56 @@
+# Maintainer: Vendicated <vendicated at riseup dot net>
+
+pkgname=armcord-git
+pkgdesc="ArmCord dev build using the system electron. ArmCordis a custom client designed to enhance your Discord experience while keeping everything lightweight"
+pkgver=r595.cdb73c3
+pkgrel=1
+
+arch=("x86_64" "aarch64")
+url="https://github.com/ArmCord/ArmCord"
+license=("custom:OSL-3.0")
+
+makedepends=("git" "nodejs" "sed")
+depends=("electron21")
+optdepends=(
+  'libnotify: Notifications'
+  'xdg-utils: Open links, files, etc'
+)
+
+provides=("armcord")
+conflicts=("armcord")
+
+source=(
+  "${pkgname}::git+${url}.git"
+  "armcord.desktop"
+  "armcord-launcher.sh"
+)
+sha256sums=('SKIP'
+            'e6b66912e1a73d0646e58f41a6c6f414f45843cdb3900a6b4cf6ae0bf12ea90f'
+            '75a212aba147ca325957263dfd67f34cc168e36d8794609326f6b616499de428')
+
+prepare() {
+    sed -i "s/%VERSION%/$pkgver/" "$srcdir/armcord.desktop"
+}
+
+pkgver() {
+	cd "$pkgname"
+	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+build() {
+  cd "$pkgname"
+  npx pnpm install --frozen-lockfile
+  npm run packageQuick
+}
+
+package() {
+  cd "$srcdir"
+
+  install -Dm 644 "$pkgname/dist/linux-unpacked/resources/app.asar" "$pkgdir/usr/share/armcord/app.asar"
+
+  install -Dm 755 "armcord-launcher.sh" "$pkgdir/usr/bin/armcord"
+  install -Dm 644 "armcord.desktop" "$pkgdir/usr/share/applications/armcord.desktop" 
+
+  install -Dm 644 "$pkgname/build/icon.png" "$pkgdir/usr/share/pixmaps/armcord.png"
+  install -Dm 644 "$pkgname/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}